[已解决]求批处理自动整理桌面文件并以日期归档望大侠指点

erjnasrtnws · 发表于 2015-11-21 16:38:05

把今天--桌面---上的（新建文件或者下载的或者粘贴复制过来的文件）无论任何类型的文件归档到归档文件夹下以日期命名（按日期年月日如20150101）的文件夹里面，只处理今天的，之前(前天明天)之后的文件都不需要要处理，补充桌面上的快捷方式也不要删除谢谢
求批处理脚本，望大侠指点
最终效果是桌面上只有我的电脑回收站归档（在归档里有20150101 20150102 20150102.。。。。。）和不是今天的文件，还有一些快捷方式。不知道我说明白了没有

望各位坛友不吝赐教！！！

1 补充如果假如归档之日期命名的文件夹中已有相同文件，请教如何不要覆盖，相同文件归档之后变成名称-1 ，名称-2 ，名称-3 这样形式的

2 还有一种情况可能难处理就是剪切到桌面上的文件，它还是以前的日期请问是否有方法把剪切过来的文件也归档到以今天日期命名的文件夹之中了（如无法解决可以不管剪切到桌面上的文件）

依山居 · 发表于 2015-11-21 21:04:16

本帖最后由依山居于 2015-11-21 21:05 编辑

没能力自己学就乖乖自己下个备份软件去。
Cobian Backup 免费开源，相当专业的文件备份软件。用过有好感。

ygqiang · 发表于 2015-11-21 22:13:34

回复 1# erjnasrtnws

@echo off & color 0d
for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do (
set "desktop_dir=%%j"
)
——————————————————————————————————————————————
set "back_dir=d:\桌面备份\%date:~0,4%-%date:~5,2%桌面备份"
set "back_dir1=%date:~0,4%-%date:~5,2%桌面备份"
set "back_dir_favo=d:\桌面备份\%date:~0,4%-%date:~5,2%桌面备份\收藏夹"
if not exist "d:\桌面备份" (md "d:\桌面备份")
if not exist "%back_dir%" (md "%back_dir%")
if not exist "%back_dir_favo%" (md "%back_dir_favo%")
1set "filesdate=%date:~0,4%%date:~5,2%%date:~8,2%"
——————————————————————————————————————————————
robocopy "%desktop_dir%" "%back_dir%" /move /e /xf *.lnk
robocopy "%userprofile%\Favorites" "d:\00beifen\备份\7Favorites" /mir /w:2 /r:2
robocopy "%userprofile%\Favorites" "%back_dir_favo%" /mir /w:2 /r:2
——————————————————————————————————————————————
for /f "delims=" %%a in ('dir /a-d /b /s "%desktop_dir%\*.*"') do (
if "%%~xa" neq ".lnk" (del "%%a" /f /s /q)
)
for /f "delims=" %%b in ('dir /ad /b /s "%desktop_dir%"^|sort /r') do (rd "%%b" /s /q)
——————————————————————————————————————————————
(echo Set objShell=CreateObject^("WScript.Shell"^)
echo DesktopPath=objShell.SpecialFolders^("Desktop"^)
echo Set objlink=objShell.CreateShortcut^(DesktopPath ^& "\%back_dir1%.lnk"^)
echo objlink.Hotkey="CTRL+Q"
echo objlink.WindowStyle=3
echo objlink.TargetPath="%back_dir%"
echo objlink.Save
)>"%temp%\mysendto.vbs"
start /wait "" "%temp%\mysendto.vbs"
cls
ping 127.0.0.1 -n 5 >nul 2>nul
del /q "%temp%\mysendto.vbs"
——————————————————————————————————————————————
title 重启explorer资源管理器不关闭打开的文件夹
1set/p "p=即将重启 Explorer，"<nul & 1pause
Call :_RestartExplorer
echo 完成！
1pause
cls
ping 127.0.0.1 -n 5 >nul 2>nul
start "" "%back_dir%"
exit
:: 重启 Explorer
goto :eof
:_RestartExplorer
( echo Set objWsh = CreateObject^("WScript.Shell"^)
echo Set objShell = CreateObject^("Shell.Application"^)
echo For Each objWin In objShell.Windows
echo If Instr^(LCase^(objWin.FullName^),"\explorer.exe"^) Then
echo strURL = strURL ^& objWin.LocationURL ^& vbCrLf
echo End If
echo Next
echo If strURL = "" Then WScript.Quit
echo strURL = Left^(strURL, Len^(strURL^)-Len^(vbCrLf^)^)
echo arrURL = Split^(strURL, vbCrLf^)
echo objWsh.run "cmd /c taskkill /f /im explorer.exe & start """" explorer", 0, True
echo For Each strURL In arrURL
echo objShell.Explore strURL
echo Next )>"%temp%\RestartExplorer.vbs"
CScript //NoLogo "%temp%\RestartExplorer.vbs"
del /q /f "%temp%\RestartExplorer.vbs"
goto :eof

复制代码

ygqiang · 发表于 2015-11-21 22:14:10

回复 1# erjnasrtnws

robocopy.exe自己网上下载。。。

依山居 · 发表于 2015-11-21 23:39:18

本帖最后由依山居于 2015-11-21 23:41 编辑

回复 4# ygqiang

取当前用户桌面路径，从当前用户变量中取，代码量应该更加少。%HOMEPATH%\desktop 这样就行了。

o(￣▽￣)o 2015/11/21 周六23:40:29.02 <(￣︶￣)>
c:\>cd %HOMEPATH%\desktop
o(￣▽￣)o 2015/11/21 周六23:40:31.45 <(￣︶￣)>
c:\Users\xxx\Desktop>

复制代码

terse · 发表于 2015-11-22 00:24:32

本帖最后由 terse 于 2015-11-25 11:17 编辑

@if(0)==(0) echo off & CScript -NoLogo -E:JScript %0 & exit @end
Date.prototype.Format = function (fmt) {
var o = {
"M+": this.getMonth() + 1,
"d+": this.getDate()
};
if (/(y+)/.test(fmt))
fmt = fmt.replace(RegExp.$1, (this.getFullYear() + "").substr(4 - RegExp.$1.length));
for (var k in o)
if (new RegExp("(" + k + ")").test(fmt))
fmt = fmt.replace(RegExp.$1, (RegExp.$1.length == 1) ? (o[k]) : (("00" + o[k]).substr(("" + o[k]).length)));
return fmt;
}
var Shell = WScript.CreateObject("WScript.Shell");
var fso = WScript.CreateObject("Scripting.FileSystemObject");
var strDesktop = Shell.SpecialFolders("Desktop");
var ff = strDesktop + "\\归档\" + new Date().Format("yyyyMMdd");
if(!fso.FolderExists(ff)){
fso.CreateFolder(ff);
};
var d = new Date();
var Folder= fso.GetFolder(strDesktop);
for(var e=new Enumerator(Folder.Files);!e.atEnd();e.moveNext()){
var f=e.item();
var t = parseInt(Math.round(d - f.Datecreated)/86400000);
if (t == 0) {
f.Move(ff+ "\" + f.name);
}
}

复制代码

ygqiang · 发表于 2015-11-22 12:28:36

回复 5# 依山居

你这个代码，xp/win7系统不通用吧？

依山居 · 发表于 2015-11-22 12:37:47

回复 7# ygqiang

开虚拟机验证了一下。有这个变量。确实不兼容，路径名是中文也就是cd %homepath%\桌面

win 7 是%homepath%\desktop

依山居 · 发表于 2015-11-22 12:56:14

测试了一下可以这样写。

cd /d "%USERPROFILE%\desktop"|| cd /d "%USERPROFILE%\桌面"

复制代码

erjnasrtnws · 发表于 2015-11-23 08:21:12

再次谢谢3楼 6楼的热心指点

erjnasrtnws · 发表于 2015-11-25 10:12:03

、回复 3# ygqiang
大侠请问，你的代码XP可以使用吗？我在XP中使用发现桌面的文件的确没有了呵呵这效果很好正好想把快捷方式留在z桌面可是在D盘的桌面备份文件夹里也是空的，不知道文件到哪里去了！代码运行时，显示删除快捷方式错误《不知道是否对运行最终结果产生影响了？？？本人希望保留快捷方式不删除
求大侠指点

erjnasrtnws · 发表于 2015-11-25 10:16:12

回复 6# terse
大侠你的代码无反应l!!!我在XP中运行的需要注意些什么了？？

terse · 发表于 2015-11-25 11:17:31

回复 12# erjnasrtnws
已修改代码第一行 echo off 后面加个 &
echo off & CScript...........
复制代码

WHY · 发表于 2015-11-25 13:31:54

本帖最后由 WHY 于 2015-11-25 13:41 编辑

@echo off
set "s=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=2*" %%i in ('reg query "%s%" /v Desktop') do (
set "Desktop=%%j"
)
for /f %%i in ('wmic os get LocalDateTime^|findstr /b [0-9]') do (
set "Today=%%i"
)
set "Today=%Today:~0,8%"
md "%Desktop%\归档\%Today%" 2>nul
set "MyPath=%Desktop:~2%"
set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%'"
for /f "tokens=1*" %%i in ('wmic datafile %wql% get creationdate^,name^|findstr /b %Today%')do (
for /f "delims=" %%j in ("%%j") do (
if /i not "%%~fj" == "%~f0" move "%%~fj" "%Desktop%\归档\%Today%"
)
)
pause

复制代码

erjnasrtnws · 发表于 2015-11-25 14:02:27

本帖最后由 erjnasrtnws 于 2015-11-25 14:14 编辑

回复 14# WHY

谢谢刚刚试了效果很好
望大侠改进！！！！！
1请问如何保留桌面的快捷方式了？？？希望把快捷方式图标留在桌面上，求指点

2，如何实现和3楼一样的效果，就是把不是今天新建的文件（是从其它盘拷贝到桌面上的不是今天的文件）也可以放入归档之中

如能实现那就对我来说相当完美了，我会终身珍藏的

本人能力低微，望大侠不吝赐教！！！！谢谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]求批处理自动整理桌面文件并以日期归档望大侠指点

评分

评分

评分

评分

评分

评分

[文件操作] [已解决]求批处理自动整理桌面文件并以日期归档 望大侠指点

评分

评分

评分

评分

评分

评分

[文件操作] [已解决]求批处理自动整理桌面文件并以日期归档望大侠指点