【已解决】批处理同时输出到控制台和文件

回家路上 · 发表于 2015-8-16 19:49:48

本帖最后由回家路上于 2015-8-17 19:28 编辑

我想执行一段批处理，需要输出到文件中，又想在控制台看到。
不用第三方（mtee）的情况下，纯批处理能做到吗？
简化例子：

@echo off
echo;前面一堆
call :somecmd
::↓↓↓↓↓↓输出到文件
call echoinfo.bat
::↑↑↑↑↑↑且实时在控制台显示
echo;后面面一堆
call :somecmd
pause & exit /b
:somecmd
echo;各种命令
goto :eof

复制代码

echoinfo.bat:

@echo off
for /l %%i in (1,1,20)do (
echo;%%i==============%%i
ping -n 2 127.1 >nul
)

复制代码

将输出内容同时输出到文件和控制台（控制台实时显示，文件无所谓）
用临时文件也行。

CrLf · 发表于 2015-8-16 21:37:25

call echoinfo.bat >输出文件.txt

复制代码

echoinfo.bat：

@echo off
for /l %%i in (1,1,20)do (
echo;%%i==============%%i
1>&2 echo;%%i==============%%i
ping -n 2 127.1 >nul
)

复制代码

回家路上 · 发表于 2015-8-16 23:03:53

回复 2# CrLf

哇哦，又长知识了。输出流和错误流竟然可以这么用。
如果例子中的【echoinfo.bat】不能改，请问还有木有办法。

CrLf · 发表于 2015-8-16 23:17:50

回复 3# 回家路上

那就用 for /f "delims=" %%a in ('call echoinfo.bat') do ...，或者其他类似思路

回家路上 · 发表于 2015-8-16 23:32:32

回复 4# CrLf

嗯，我也有在想用for循环行不，但是将call xxx命令放在for里

for /f "delims=" %%a in ('call echoinfo.bat') do ...

复制代码

这种必须等到call命令执行完，for才去解析文本，
所以我觉得行不通，我在想是否用临时文件是否能。
但没想到在一个批处理里同时写/读/分析一个文本文件怎么搞。
。。。

CrLf · 发表于 2015-8-16 23:41:15

回复 5# 回家路上

那就没辙了

回家路上 · 发表于 2015-8-17 13:40:58

回复 6# CrLf
嗯，试了，用start也不能同时写和读文件。看来确实不行。谢啦。

CrLf · 发表于 2015-8-17 14:45:37

回复 7# 回家路上

用 type 可以在写入的同时读文件，不过只能读到已经写入的部分

回家路上 · 发表于 2015-8-17 19:25:56

本帖最后由回家路上于 2015-8-18 14:14 编辑

回复 8# CrLf

嘿，果然诶。我试了试type真的可以展示文件内容。这就是我想要的。然后我转念一想，more会不会也可以呀，可以的话就更容易实现将日志输出到控制台。
一试果然可以，就做了一个DEMO。写的不好，但是行得通哈。

@echo off&if not %1.==. call%*&exit
:: DEMO
:: 模拟调用一个外部程序，将其输出记录入日志文件同时输出到控制台。
set "logfile=%~dp0log.txt"
set "tmpfile=%~dp0$tmp$"
::起一个线程读文件
::↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓
start /b %~s0 :showinfo %logfile% %tmpfile%
::↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑
if exist "%tmpfile%" del /q "%tmpfile%"
if exist "%logfile%" del /q "%logfile%"
for /l %%i in (3,-1,0) do ping -n 2 127.1 >nul&echo;%%i秒后开始执行并记录日志。。。
::模拟记录日志文件向文本输入文件
call :writeinfo>%logfile% & cd.>%tmpfile%
for /l %%i in (0,1,3) do ping -n 2 127.1 >nul&echo;完事了，再干点别的什么。
pause & exit /b
:showinfo
set "logfile=%~1" & set "tmpfile=%~2"
setlocal enabledelayedexpansion
:show
if exist "%~1" (
if "%idx%" lss "0" for /f %%i in ('more !logfile!^|find /c /v ""') do set "idx=%%i"
if "%idx%" geq "0" (
for /f "delims=" %%i in ('more +%idx% !logfile!^|findstr /n .*') do (
set info=%%i
echo;!info:*:=!
set /a idx+=1
)
)
ping -n 1 127.1 >nul
)
if exist "!tmpfile!" (
del /q "!tmpfile!"&goto :eof
)
goto :show
:writeinfo
if 1%a% geq 130 goto :eof
set /a a+=1,gap=%random%%%5
echo;%a%======%gap%======%a%
ping -n %gap% 127.1 >nul
goto :writeinfo

复制代码

谢谢啦。O(∩_∩)O！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] 【已解决】批处理同时输出到控制台和文件

标题

评分