[已解决]求批处理删除文本指定字符的指定内容

toobat · 发表于 2015-4-11 11:33:51

本帖最后由 toobat 于 2015-4-13 10:21 编辑

在"C:\播放器\setting.ini"里的内容：

[music]
log_play=201504101624
open=CD12
[history]
login0=201504101623
login1=201504101623

1.把log_play那行整行删掉
2.把open=CD12只删掉CD12就是等号后面的
3.删掉[history]的包括的内容，就是删掉下面内容：

[history]
login0=201504101623
login1=201504101623

不过[history]有时候后面多出[update]的内容
[history]
login0=201504101623
login1=201504101623
[update]
update=201503021105

bailong360 · 发表于 2015-4-11 18:48:27

本帖最后由 bailong360 于 2015-4-12 13:39 编辑

@echo off
setlocal enabledelayedexpansion
(for /f "useback tokens=1,2* delims==" %%i in ("C:\播放器\setting.ini") do (
set value=%%i
if not "%%j"=="" (set str=%%i=%%j) else set str=%%i
if "%%i"=="log_play" (
set str=
) else if "%%i"=="open" set str=%%i=
if "%%i"=="[history]" (
set skip=
) else if "!value:~0,1!"=="[" set skip=0
if not "!str!"=="" (
if not "!skip!"=="" echo !str!)
))>$tmp
move /y "$tmp" "C:\播放器\setting.ini"

复制代码

pcl_test · 发表于 2015-4-11 21:33:22

回复 2# bailong360

bailong360 · 发表于 2015-4-11 21:45:08

回复 3# pcl_test

感谢

toobat · 发表于 2015-4-12 07:59:22

回复 2# bailong360

多谢解答，不过现在[xx]后面的多了个=

[music]=
open=
[history]=
login0=201504101623
login1=201504101623
[update]=
update=201503021105

bailong360 · 发表于 2015-4-12 08:13:29

回复 5# toobat

已修改

toobat · 发表于 2015-5-9 16:14:39

回复 6# bailong360

bailong360大哥，可不可以再请教一下：

1.如果有多项像log_play整行删掉的，该怎样添加修改？
2.如果有多项open=CD12只删掉CD12就是等号后面的，该怎样添加修改？
3.不用删除[history]那项，该怎样添加修改？

bailong360 · 发表于 2015-5-9 23:11:17

@echo off
setlocal enabledelayedexpansion
(for /f "useback tokens=1,2* delims==" %%i in ("C:\播放器\setting.ini") do (
set value=%%i
if not "%%j"=="" (set str=%%i=%%j) else set str=%%i
for %%a in ("log_play" "log_play2") do if "%%i"==%%a set str=
for %%a in ("open" "open2") do if "%%i"==%%a set str=%%i=
if not "!str!"=="" (echo !str!)
))>$tmp
move /y "$tmp" "C:\播放器\setting.ini"

复制代码

toobat · 发表于 2015-5-10 18:19:39

回复 8# bailong360

能用到log_play*这样的通配符来代替相似的吗？

bailong360 · 发表于 2015-5-10 18:41:31

回复 9# toobat
不能...

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]求批处理删除文本指定字符的指定内容

评分

评分

评分

评分