[已解决]求批处理实现重命名文件夹只保留前5个字符

crownking1983 · 发表于 2015-3-28 11:56:36

求一个批处理，将所有文件夹只保留前5个字符，如处理后可能存在同名文件夹，则只处理第一个第二个不做任何处理。实例——
比如一堆文件夹,文件夹名如下
ABCDEFG
HIJKLMN
OPQRST
ABCDETYU
LSKDJNRE
………… 等等成百上千个

处理后文件名重命名只保留前5个字符，变为——
ABCDE
HIJKL
OPQRS
ABCDETYU （注意，这个如果保留前5个字符将与第一个重名，故此这个批处理需要智能一些，遇到这个情况第二个文件夹就不做修改）
LSKDJ

难了我好几天了，跪求大神

pcl_test · 发表于 2015-3-28 12:04:06

回复 1# crownking1983

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /ad /b') do (
set name=%%a
if not exist "!name:~,5!" ren "%%a" "!name:~,5!"
)
pause

复制代码

crownking1983 · 发表于 2015-3-28 13:52:34

回复 2# pcl_test

大哥牛逼。小弟还有一个问题想问问，引申一下，如果是按这个规则，要改诸多文件夹里的文件，重命名所有文件只保留前5个字符的话，（文件夹名不改只改里面的文件）那么求这个批处理命令全文

pcl_test · 发表于 2015-3-28 14:17:15

回复 3# crownking1983

@echo off
for /f "delims=" %%i in ('dir /ad /b') do (
pushd "%%i"
for /f "delims=" %%a in ('dir /a-d /b') do (
set name=%%a
setlocal enabledelayedexpansion
if not exist "!name:~,5!%%~xa" ren "%%a" "!name:~,5!%%~xa"
endlocal
)
popd
)
pause

复制代码

crownking1983 · 发表于 2015-3-28 15:16:47

回复 4# pcl_test

太牛逼了，小弟五体投地。最后引申一步，如果依然按这个规则，改诸多文件夹以及这些文件夹里面的文件，重命名所有文件夹以及里面的文件都只保留前5个字符的话，（文件夹名和里面的文件都同时这样处理）那么求这个批处理命令全文。
大哥别怪小弟矫情没完没了，这是最后一次问您了。没有别的原因，我主要是想通过您发的批处理命令全文对比里面有什么不同，从而进一步掌握文件夹批处理、文件批处理以及文件夹和文件同时批处理的BAT指令。

pcl_test · 发表于 2015-3-28 15:37:55

回复 5# crownking1983

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /ad /b') do (
pushd "%%i"
for /f "delims=" %%a in ('dir /a-d /b') do (
set name=%%a
if not exist "!name:~,5!%%~xa" ren "%%a" "!name:~,5!%%~xa"
)
popd
set fname=%%i
if not exist "!fname:~,5!" ren "%%i" "!fname:~,5!"
)
pause

复制代码

wpy4206 · 发表于 2017-8-12 17:47:33

回复 2# pcl_test
不小心重名搞错了，怎么重命名去掉添加的这5位呢？

极度凶残 · 发表于 2021-6-5 21:33:49

回复 4# pcl_test

老大就是厉害，正需要，收藏了，谢谢分享！

kimpppg · 发表于 2021-6-14 11:35:42

回复 6# pcl_test

批量的保留前8位的字符。后面的字符随机的所以打算删掉。我把5改成8，怎么没效果。请指教

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]求批处理实现重命名文件夹只保留前5个字符

评分

评分

评分