[已解决]批次命名文件並在文件後加上該文件的建立日期

我不是是人 · 发表于 2015-1-26 16:14:24

本帖最后由我不是是人于 2015-1-28 13:07 编辑

批次將某文件夾中所有文件的後面加上該文件建立日期
比如:我有文件名稱:1.pdf  建立日期:2015-1-1
            文件名稱:2.pdf  建立日期:2015-1-2
            文件名稱:3.pdf  建立日期:2015-1-3 如此類推
我希望可以批次將它們改成
文件名稱:1_2015-1-1.pdf
文件名稱:2_2015-1-2.pdf
文件名稱:3_2015-1-3.pdf 如此類推

希望有大神可以幫幫小弟我

感恩~

34205 · 发表于 2015-1-26 16:23:44

使用论坛搜索功能，有相关的主题帖了哦

我不是是人 · 发表于 2015-1-26 16:37:41

我看過類似的
http://www.bathome.net/viewthrea ... hlight=%C3%FC%C3%FB

不過這個是當前日期><

我想要的是文件建立的日期

pcl_test · 发表于 2015-1-26 17:53:27

回复 1# 我不是是人
一、
支持选中单个或多个文件重命名
请以管理员身份运行该批处理，因为需写入注册表，如果被杀软拦截，请选择允许运行或先退出杀软

@echo off
echo @echo off>"C:\Program Files\文件名添加创建日期.bat"
echo for /f "skip=1 tokens=1-3 delims=-/ " %%%%a in ('dir /tc "%%1"^^^|findstr ":"') do set "getdate=%%%%a-%%%%b-%%%%c">>"C:\Program Files\文件名添加创建日期.bat"
echo ren %%1 "%%~n1_%%getdate%%%%~x1">>"C:\Program Files\文件名添加创建日期.bat"
reg add "HKCR\*\shell\文件名添加创建日期\Command" /ve /t REG_SZ /d ""C:\Program Files\文件名添加创建日期.bat" "%%1"" /f
echo 建立“文件名添加创建日期”右键菜单成功！
pause

复制代码

二、

@echo off
cd /d "D:\test"
for /f "delims=" %%i in ('dir /a-d /b') do (
for /f "skip=1 tokens=1-3 delims=-/ " %%a in ('dir /tc "%%i"^|findstr ":"') do (
ren %%i "%%~ni_%%a-%%b-%%c%%~xi"
)
)
echo 更名完成！
pause

复制代码

apang · 发表于 2015-1-26 22:09:05

本帖最后由 apang 于 2015-2-2 18:21 编辑

@echo off
set "srcDir=D:\Test"
call :Lp "%srcDir%"
pause & exit/b
:Lp
set "p=%~p1"
set "w=wmic DataFile where "Drive='%~d1' and Path='%p:\=\\%'" get CreationDate^,Name"
for /f "tokens=1*" %%a in ('%w% 2^>nul^|findstr /b [0-9]') do (
set "D=%%a"
for /f "delims=" %%c in ("%%b") do (
set "file=%%~fc"
set "Name=%%~nc"
setlocal enabledelayedexpansion
echo,ren "!file!" "!Name!_!D:~,4!-!D:~4,2!-!D:~6,2!%%~xc"
endlocal
)
)
for /d %%a in ("%~1*") do call :Lp "%%a"

复制代码

CrLf · 发表于 2015-1-26 22:14:15

1>1/* : www.bathome.net
@echo off
dir /a-d /b *.txt | cscript -nologo -e:jscript "%~0"
pause & exit /b
*/
var files = WScript.StdIn.ReadAll().split(/\r\n/)
var fso = new ActiveXObject("Scripting.FileSystemObject")
for(var i in files){
var file = fso.GetFile(files[i])
var tc = new Date(file.DateCreated)
file.Move(fso.GetBaseName(file.Name) + '_' + tc.getFullYear() + '-' + (tc.getMonth()+1) + '-' + tc.getDate() + '.' + fso.GetExtensionName(file.Name))
}

复制代码

CrLf · 发表于 2015-1-26 23:57:12

来个 powershell

dir *.pdf | ren -newname {$_.basename + $_.CreationTime.toString('_yyyy-M-d') + $_.Extension}

复制代码

我不是是人 · 发表于 2015-1-27 17:21:14

非常謝謝各位大神的熱心幫忙,小弟正在消化中(我的大腦試圖去了解內容)(腦死中)XDD

失独家庭 · 发表于 2024-11-28 11:09:01

本帖最后由失独家庭于 2025-1-15 20:20 编辑

非常感谢，用上了

rem 创建日期
dir *.pdf | ren -newname {$_.basename + $_.CreationTime.toString('_yyyy-M-d') + $_.Extension}
rem 修改日期
dir *.pdf | ren -newname {$_.lastwriteTime.toString('[yy-MM]') + $_.basename + $_.Extension}
dir *.* | ren -newname {$_.lastwriteTime.toString('[yy-MM]') + $_.basename + $_.Extension}
http://www.bathome.net/thread-34043-1-1.html

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批次命名文件並在文件後加上該文件的建立日期

评分

评分

评分

评分

浏览过的版块