[ 新手习题 6 ] 批处理添加汉字行号

wxcute · 发表于 2008-11-17 09:07:05

a.txt

要怎么学好批处理？
可潜水看帖，静静研究；
可看教程做习题，然后解决实际的问题；
也可二者并用取其优，当然还有其他方法。
你是怎么做的呢？

复制代码

以上文本有五行，要求显示如下：（行号可为大写，但必须是汉字）

一┃要怎么学好批处理？
二┃可潜水看帖，静静研究；
三┃可看教程做习题，然后解决实际的问题；
四┃也可二者并用取其优，当然还有其他方法。
五┃你是怎么做的呢？

复制代码

方法不限。答对加分鼓励，第一个最多。

上一题：[ 新手练习 5 ] 随机显示星期几
http://bbs.bathome.net/thread-2564-1-1.html
下一题：[ 新手练习 7 ] 把所有输出都写入一个文件
http://bbs.bathome.net/thread-2582-1-1.html

[ 本帖最后由 wxcute 于 2008-11-18 21:04 编辑 ]

chengyuan383 · 发表于 2008-11-17 10:59:07

@echo off
@echo 一┃要怎么学好批处理？
@echo 二┃可潜水看帖，静静研究；
@echo 三┃可看教程做习题，然后解决实际的问题；
@echo 四┃也可二者并用取其优，当然还有其他方法。
@echo 五┃你是怎么做的呢
pause

复制代码

wxcute · 发表于 2008-11-17 11:06:27

小心我扣你分　^_^　。代码括起来也用错了，应该是 code

是要通过批处理读取 a.txt 文件。

[ 本帖最后由 wxcute 于 2008-11-17 11:08 编辑 ]

pusofalse · 发表于 2008-11-17 14:32:14

a.txt中内容是固定的、总在10行之内？还是未知多少行呢？

lhjoanna · 发表于 2008-11-17 15:06:44

看错了，|和┃不一样啊！
粗的┃情况：

@echo off&setlocal enabledelayedexpansion
set "head=一二三四五"
set /a num=0
for /f %%i in (a.txt) do (
call echo %%head:~!num!,1%%┃%%i
set /a num+=1
)
pause

复制代码

"或"字符|:

@echo off&setlocal enabledelayedexpansion
set "head=一二三四五"
set /a num=0
for /f %%i in (a.txt) do (
call set /p=%%head:~!num!,1%%<nul
set /p=^|%%i<nul
echo.
set /a num+=1
)
pause>nul

复制代码

[ 本帖最后由 lhjoanna 于 2008-11-17 20:39 编辑 ]

wxcute · 发表于 2008-11-17 15:37:18

总在 10 行之内吧，暂不考虑过多行数的。

mingming1205 · 发表于 2008-11-17 16:27:15

@echo off
set "var="
setlocal enabledelayedexpansion
for %%i in (一二三四五) do (
set /a var+=1
set ,!var!=%%i
)
set "var="
for /f "eol= delims=" %%a in (a.txt) do (
call :sub %%a
)
pause>nul
exit
:sub
set /a var+=1
echo !,%var%!┃%1
goto :eof

复制代码

[ 本帖最后由 mingming1205 于 2008-11-17 16:31 编辑 ]

pusofalse · 发表于 2008-11-17 16:28:31

是，如果未知多少行，不知要难多少倍了。

batman · 发表于 2008-11-17 19:07:29

适用于1－99行的：

@echo off&setlocal enabledelayedexpansion
set "str=一二三四五六七八九十"
for %%i in (%str%) do set /a n+=1&set "_!n!=%%i"
for /f "tokens=1* delims=:" %%i in ('findstr /n .* a.txt') do (
set "a=%%i"
if "!a:~1!" equ "" (
echo !_%%i!行 %%j
) else (
call,echo %%_!a:~,1!%%十%%_!a:~1!%%行 %%j
)
)
pause>nul

复制代码

同理可写适于1－999行，1－9999行，1－9.........9行，只要再设置个变量set "var=十百千万...."

BBCC · 发表于 2008-11-17 20:40:34

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION&set "code=一二三四五"&set a=
goto :main
:head
set str=%1
set /a a+=1
for /f "tokens=%a% delims= " %%b in ("%code%") do (
set str%a%=!str:%a%=%%b!
set str%a%=!str%a%::=┃!)
goto :eof
:main
for /f "delims=" %%a in ('findstr/n . a.txt') do (call :head %%a)
for /l %%b in (1 1 5) do (echo. !str%%b!)
pause

复制代码

不知道合要求不?

BBCC · 发表于 2008-11-17 20:44:01

跟batman的速度比较还是比较差...
batman
20:42:17.31 20:42:17.35
小弟
20:43:02.04 20:43:02.09

batman · 发表于 2008-11-17 21:53:13

1－99999行的：

@echo off&setlocal enabledelayedexpansion
set "str=一二三四五六七八九"&set "var=万千百十零"
for %%i in (%str%) do set /a n+=1&set "_!n!=%%i"
for /f "tokens=1* delims=:" %%i in ('findstr /n .* a.txt') do (
set "a=%%i"&call :lp
call,set "b=%%var:~-!m!%%"&set "m=0"
set "a=%%i"
call :loop %%i "%%j"
)
pause>nul&goto :eof
:lp
set "a=%a:~1%"&set /a m+=1
if defined a goto lp
goto :eof
:loop
if %1 lss 10 (
call,set "string=%string%零%%_!a:~,1!%%"
) else (
if %a:~,1% equ 0 (
set "string=%string%零"
) else (
if "%b:~,1%" neq "零" (
call,set "string=%string%%%_!a:~,1!%%%b:~,1%"
) else (
call,set "string=%string%%%_!a:~,1!%%"
)
)
)
set "b=%b:~1%"&set "a=%a:~1%"
if defined a goto loop
set "string=%string:零零零=零%"
set "string=%string:零零=零%"
if "%string:~-1%" equ "零" set "string=%string:~,-1%
set "string=%string%行　　　　　　　　　"
echo %string:~,9% %~2&set "string="

复制代码

测试文本a.txt由下面的代码生成

@echo off
for /l %%i in (1,1,99999) do echo %%i>>a.txt

复制代码

batman · 发表于 2008-11-18 11:36:23

真的是如此，查找了原因，原来是在call中出的问题，当%%j中含有空格时要用双引号引
起，并在后面输出时将引号去掉：call :loop %%i "%%j" echo %string:~,9% %~2
ps:兄弟不用给我加分，呵呵。

BAT1 · 发表于 2008-11-24 19:23:31

你那个代码害的我差点死机了。
使用的时候把99999改成999就很多了

skuny · 发表于 2009-1-14 20:03:30

@echo off&setlocal enabledelayedexpansion
call :111 一二三四五
pause>nul&goto :eof
:111
for /f %%i in (a.txt) do (
set /a num+=1
call echo %%!num!┃%%i
)
goto :eof

复制代码

[ 本帖最后由 skuny 于 2009-1-14 20:05 编辑 ]

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[ 新手习题 6 ] 批处理添加汉字行号

评分

我不知道是不是这样啊。

评分

回复 2楼的帖子

评分

回复 4楼的帖子

评分

回复 6楼的帖子

评分

评分

评分

回复 12楼的帖子

评分

浏览过的版块

[ 新手习题 6 ] 批处理添加汉字行号

评分

我不知道是不是这样啊。

评分

回复 2楼 的帖子

评分

回复 4楼 的帖子

评分

回复 6楼 的帖子

评分

评分

评分

回复 12楼 的帖子

评分

浏览过的版块

回复 2楼的帖子

回复 4楼的帖子

回复 6楼的帖子

回复 12楼的帖子