【已解决】BAT：如何将文件夹内特定应用程序的名称，批量更改为上一级文件夹的名称

思想之翼 · 发表于 2014-9-19 03:35:22

本帖最后由思想之翼于 2014-9-20 20:16 编辑

d:\文本\文本1\001\运行.exe
d:\文本\文本1\002\运行.exe
...
d:\文本\文本1\210\运行.exe
如何将运行.exe的名称，批量更改为上一级文件夹的名称，即更改为：
d:\文本\文本1\001\001.exe
d:\文本\文本1\002\002.exe
...
d:\文本\文本1\210\210.exe

yu2n · 发表于 2014-9-19 11:09:25

@echo off
set "strPath=d:\文本\文本1"
for /f "delims=" %%a in ('dir /a-d/b/s "%strPath%\*.exe"') do (
for /f "delims=" %%b in ("%%a\..") do move "%%~fa" "%%~fb%%~xa"
)
pause

复制代码

思想之翼 · 发表于 2014-9-19 17:10:53

回复 2# yu2n

感谢您的帮助！

经过测试，代码是将运行.exe 改名后移出文件夹。能否不移动，改名后依然还在原来的文件夹里？

yu2n · 发表于 2014-9-19 17:11:59

回复 3# 思想之翼
你的意思是将 move 改为 copy ?

@echo off
set "strPath=d:\文本\文本1"
for /f "delims=" %%a in ('dir /a-d/b/s "%strPath%\*.exe"') do (
for /f "delims=" %%b in ("%%a\..") do copy "%%~fa" "%%~fb%%~xa"
)
pause

复制代码

思想之翼 · 发表于 2014-9-19 17:19:10

本帖最后由思想之翼于 2014-9-19 17:28 编辑

回复 4# yu2n

d:\文本\文本1\001\运行.exe
运行.exe在d:\文本\文本1\001\内

运行.exe改名为001.exe后，依然还在d:\文本\文本1\001\内，仅仅是将运行.exe改名为001.exe，不移动，也不拷贝。可以理解为用001.exe替换运行.exe

yu2n · 发表于 2014-9-19 18:02:40

回复 5# 思想之翼
... Sorry，我看错题了。
按题意如下：

set "strPath=d:\文本\文本1"
for /f "delims=" %%a in ('dir /a-d/b/s "%strPath%\*.exe"') do (
for /f "delims=" %%b in ("%%a\..") do rename "%%~fa" "%%~nb%%~xa"
)
pause

复制代码

CrLf · 发表于 2014-9-20 01:05:02

本帖最后由 CrLf 于 2014-9-20 01:06 编辑

回复 6# yu2n

个人比较喜欢暴力一点：

@echo off
set "strPath=d:\文本\文本1"
(for /f "delims=" %%a in ('dir /ad/b/s "%strPath%"') do (
ren "%%a\*.exe" "%%~na.exe"
)) 2>nul
pause

复制代码

批处理到底还是慢，处理通配发生的错误比挨个判断哪个需要处理更快

yu2n · 发表于 2014-9-20 01:10:59

回复 7# CrLf
哦。多谢指点。

tmplinshi · 发表于 2014-9-20 01:36:41

本帖最后由 tmplinshi 于 2014-9-20 01:40 编辑

dir /b /a:d /s "d:\文本\文本1" | do ren "%a\运行.exe" "%~nxa.exe" 2>nul

复制代码

do.bat 在这里下载: http://bathome.net/thread-20477-1-10.html

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】BAT：如何将文件夹内特定应用程序的名称，批量更改为上一级文件夹的名称

评分

评分

评分