【已解决】批处理：批量提取特定位置的数据

思想之翼 · 发表于 2014-8-3 23:23:01

文件夹C:/文本1/ 内有210个txt文本，分别命名为001-210.txt。每个txt文本内有两行数据，格式见附件。第一行数据有9个空心圈，1个实心圈；第二行是10个数据。现在欲根据实心圈的位置，提取对应位置的第二行数据，用bat、vbs能够实现吗？
举例：
001.txt 文本内的数据为：
117 92--9023465718 ●○○○○○○○○○
1397820564
第一行10个圈，实心圈位于第一位，则提取第二行10个数据的第一位 1 ，写入C:/文本2/ 内的001.txt文本
若第一行10个圈实心圈位于第二位，则提取第二行10个数据的第二位 3 ，写入C:/文本2/ 内的001.txt文本

再世情緣 · 发表于 2014-8-3 23:40:08

回复 1# 思想之翼

问下所有文本1里面的txt文档的格式是一样的吗？
比如：第一行都是
xxx[空格]xxx--xxx[空格]圈圈圈...
xxx代表若干数字

思想之翼 · 发表于 2014-8-3 23:41:01

本帖最后由思想之翼于 2014-8-4 00:06 编辑

回复 2# 再世情緣

谢谢关注！
是的，所有txt文档的格式是一样的。
第一行圆圈前有数据+空格共19个
第二行数据前有空格共11个

再世情緣 · 发表于 2014-8-4 00:09:51

本帖最后由再世情緣于 2014-8-4 00:17 编辑

回复 3# 思想之翼

在附件里多添加点txt文档，我试验下
赶紧的，代码基本已将完成。。。只待我试验下。。。。

思想之翼 · 发表于 2014-8-4 00:22:13

回复 4# 再世情緣

好的。谢谢您！

再世情緣 · 发表于 2014-8-4 00:33:01

回复 5# 思想之翼

额。。。文件夹名字到底是“文件夹1” 还是 “文本1”。。。。

再世情緣 · 发表于 2014-8-4 00:42:32

本帖最后由再世情緣于 2014-8-4 00:44 编辑

@echo off &setlocal enabledelayedexpansion &color 0a
set "var=%cd%"
set "file=文件夹"
pushd %var% >nul
mkdir "%file%2" >nul 2>nul
for /f "delims=" %%a in ('dir /b /a -d /s "%file%1\*.txt" 2^>nul') do (
set "txtpath=%%~fa"
set "txtname=%%~nxa"
call :main !txtpath!
pause.>nul
)
pause.
call exit
:main
for /f "usebackq tokens=3 delims= " %%a in ("%1") do (
set "code0=%%a" &&set "code0=!code0: =!"
set "code=!code0:*●=!"
call :getlen
for /f "usebackq skip=1" %%a in ("%1") do (
set "code2=%%a" &&set "code2=!code2: *=!"
call :getnum
)
)
echo.当前处理文件：[!txtname!]
echo.获取第一行有效字符：[!code0!]
echo.获取第二行有效字符：[!code2!]
echo.第一行 ● 所在位置：!len!
echo.第二行第 !len! 个字符为： [!num!]
echo.写入 [!num!] -^> "%cd%\!file!2\!txtname!"
(echo.!num!)>"%cd%\!file!2\!txtname!"
goto :eof
:getlen
if "!code!" EQU "" (
set /a "len=10"
goto :eof
)
set /a "i=0"
:getlen_main
set "code1=!code:~%i%,1!"
if "!code1!" NEQ "" (
set /a "i+=1"
goto :getlen_main
)
set /a "len=10-i"
goto :eof
:getnum
set /a "len0=len-1"
set "num=!code2:~%len0%,1!"
goto :eof

复制代码

说明：保存为bat之后，放在“文件夹1”同目录下，代码第三行

set "file=文件夹"

复制代码

这里自定义你的文件夹的名字，不用带后面的数字，有问题回复我
代码中间

echo.当前处理文件：[!txtname!]
echo.获取第一行有效字符：[!code0!]
echo.获取第二行有效字符：[!code2!]
echo.第一行 ● 所在位置：!len!
echo.第二行第 !len! 个字符为： [!num!]
echo.写入 [!num!] -^> "%cd%\!file!2\!txtname!"

复制代码

部分为cmd窗口显示内容，可以删除，注意别把

(echo.!num!)>"%cd%\!file!2\!txtname!"

复制代码

也删了。。。

代码可能会很繁琐。。。。

思想之翼 · 发表于 2014-8-4 00:58:18

回复 7# 再世情緣

谢谢您的帮助！
经测试，只能自动提取001.txt，之后按一次回车键运行002.txt，再按回车键运行003.txt...要不停地按回车键

再世情緣 · 发表于 2014-8-4 01:03:57

本帖最后由再世情緣于 2014-8-4 01:22 编辑

回复 8# 思想之翼

额。。。。这是我自己测试的时候，为了查错，弄的，你把第十行

pause.>nul

复制代码

删了就好了，或者改为

rem pause.>nul

复制代码

注释掉也行

思想之翼 · 发表于 2014-8-4 01:12:29

回复 9# 再世情緣

谢谢您给予的大力帮助，测试后解决问题。
但是产生了一个新问题：
需要提取“文本1”里的210个txt数据，写入“文件夹1”
需要提取“文本2”里的210个txt数据，写入“文件夹2”
需要提取“文本3”里的210个txt数据，写入“文件夹3”
...
您写的代码，修改哪里？

xxpinqz · 发表于 2014-8-4 01:12:53

回复 7# 再世情緣

取位置不用那么麻烦，类似这样：

@echo off&setlocal enabledelayedexpansion
set "a=1397820564"
set "b=117 92--9023465718 ●○○○○○○○○○#a9876543210"
set "b=%b:*●=%"
set /a len=0x%b:~10,1%
echo,!a:~-%len%,1!
pause

复制代码

再世情緣 · 发表于 2014-8-4 01:14:07

回复 10# 思想之翼

。。。。你的意思是还有好多类似的文本1.....文件夹？？

再世情緣 · 发表于 2014-8-4 01:16:23

回复 11# xxpinqz

额。。。。佩服！！！你脑袋怎么长得。。。。怎么能想出来如此办法。。。

思想之翼 · 发表于 2014-8-4 01:24:28

回复 13# 再世情緣

再经过测试，代码出错了：改变110.txt 181.txt 190.txt 等文本的数据（格式不变），得到的结果依然是原先的数据。

xxpinqz · 发表于 2014-8-4 01:26:53

本帖最后由 xxpinqz 于 2014-8-4 01:44 编辑

回复 13# 再世情緣

拾人牙慧而已，这算法是大佬们写的。
http://www.bathome.net/thread-5861-1-1.html
http://www.bathome.net/viewthread.php?tid=11799&highlight=
大体这样会提升点效率：

@echo off&setlocal enabledelayedexpansion
cd /d "C:\文本1"
for %%i in (*.txt) do (
for /f "tokens=*" %%a in (%%i) do (
if defined str (
set "num=%%~nxa"
for %%b in (!len!) do echo,!num:~-%%b,1!
set "str="
) else (
set "str=%%~nxa#a9876543210"
set "str=!str:*●=!"
set /a len=0x!str:~10,1!
)
)
)>"C:\文件夹1\%%~nxi"

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理：批量提取特定位置的数据

评分

评分

评分