[已解决]批处理如何删除/去掉文本中每一行数字最前面的0

非常感谢 · 发表于 2013-10-7 23:12:57

本帖最后由 pcl_test 于 2016-11-26 13:54 编辑

一个文件夹下有多个txt文件（001.txt， 002.txt， gsh.txt, llk.txt, dhhdkkk.txt, 1233czcc.txt 等等，）名字各异。内容都是数字格式。请看批处理前和后的对比。
批处理前：
01088888888
045199999999
043377777777
12399999999
222334888999
38899999999
48898989999
5889999000
68879970700707
7886666666
87678888888
9888888888

批处理后：
1088888888
45199999999
43377777777
12399999999
222334888999
38899999999
48898989999
5889999000
68879970700707
7886666666
87678888888
9888888888

另外有批处理零基础视频教程可以介绍吗？谢谢！

Batcher · 发表于 2013-10-7 23:15:29

http://www.bathome.net/thread-14608-1-1.html

apang · 发表于 2013-10-7 23:18:20

是文件名还是文件内容？

DAIC · 发表于 2013-10-7 23:21:18

看起来像是电话号码，是不是每个文件名最前面有且只有一个0啊？

Lumiere · 发表于 2013-10-8 03:48:19

回复 1# 非常感谢

for %%a in (0*.txt) do set n=%%~na&call set n=%%n:~1%%&call ren %%a %%n%%.txt

复制代码

非常感谢 · 发表于 2013-10-8 11:30:16

本帖最后由非常感谢于 2013-10-8 11:52 编辑

回复 3# apang

如a文件夹里面有001，002，003，aa,bb,,cc.......等txt文本文件。里面内容像主题一样。批处理就是对所有文本文件里的内容去掉最前面的0,如果是13899999999，52699999999，的话因为不带0就都保留好了，，，谢谢！

非常感谢 · 发表于 2013-10-8 11:32:50

本帖最后由非常感谢于 2013-10-8 11:49 编辑

回复 4# DAIC

只去掉0就好了，其他保留就好，主题从新修正了一下，谢谢。

非常感谢 · 发表于 2013-10-8 11:37:16

回复 5# Lumiere

对不起，可能我没表述清楚主题。从新修正了，谢谢！

非常感谢 · 发表于 2013-10-8 12:14:41

回复 2# Batcher

谢谢！！！

DAIC · 发表于 2013-10-8 14:23:45

回复 7# 非常感谢

有没有开口连续两个或多个0的情况？

apang · 发表于 2013-10-8 16:00:38

去掉每一行开头的所有0

@echo off
for /f "delims=" %%i in ('dir /a-d/b *.txt') do (
(for /f "usebackq tokens=*" %%a in ("%%i") do (
for /f "tokens=*delims=0" %%b in ("%%a") do echo,%%b
))>$
move $ "%%i"
)
pause

复制代码

只去掉每一行开头的第一位0

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d/b *.txt') do (
(for /f "usebackq tokens=*" %%a in ("%%i") do (
set "a=%%a"
if "!a:~,1!"=="0" set "a=!a:~1!"
echo,!a!
))>$
move $ "%%i"
)
pause

复制代码

非常感谢 · 发表于 2013-10-8 17:13:12

本帖最后由非常感谢于 2013-10-8 17:16 编辑

回复 11# apang

非常感谢，apang,上面两个代码都很好，珍藏先！！！
@echo off
echo 很喜欢批处理之家
pause

DAIC · 发表于 2013-10-8 17:25:32

sed -i "s/^0\+//" *.txt

复制代码

非常感谢 · 发表于 2013-10-8 21:40:54

回复 13# DAIC
测试数据没有变化。谢谢！

DAIC · 发表于 2013-10-8 22:02:46

回复 14# 非常感谢

可能是你的sed版本问题

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何删除/去掉文本中每一行数字最前面的0

评分

评分

评分