批处理如何将文档中的null + 之后的制表符替换为换行符？

zjfy22 · 发表于 2013-9-17 14:42:40

请教几个问题，原格式如下：
1053 001 09-04-2013 13:20:11 460.0000 0 NULL HOT 1053 001
1053 002 09-04-2013 14:39:53 863.0000 0 NULL HOT 1053 002

1、如何将指定文件夹（D:\File\）下的所有的txt替换，不知道txt的名称，将文本中NULL和后面的制表符替换成换行符（格式如下）

1053 001 09-04-2013 13:20:11 460.0000 0
HOT 1053 001
1053 002 09-04-2013 14:39:53 863.0000 0
HOT 1053 002
2. 不生成新的txt 直接在原txt中修改保存。
新人请高手指点！

terse · 发表于 2013-9-17 15:06:35

本帖最后由 terse 于 2013-9-18 13:32 编辑

不处理特殊字符

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "tokens=*" %%a in ('dir /b /a-d d:\file\*.txt') do (
(for /f "usebackq delims=" %%i in ("%%a") do (
set "str=%%i"
set str=!str:%tab%null=^
!
for /f "tokens=*" %%j in ("!str!") do echo %%j
))>$
move $ "%%a"
)
pause

复制代码

先FINDSTR处理下

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
set "ph=d:\file"
for /f "tokens=*" %%a in ('findstr /imc:"%tab%null" %ph%\*.txt') do (
(for /f "usebackq delims=" %%i in ("%%a") do (
set "str=%%i"
set str=!str:%tab%null=^
!
for /f "tokens=*" %%j in ("!str!") do echo %%j
))>$
move $ "%%a"
)
pause

复制代码

Batcher · 发表于 2013-9-17 15:41:57

如果2楼的代码没能解决问题，请把你的原始文件压缩一下传上来，以便大家测试。

zjfy22 · 发表于 2013-9-18 11:26:39

感谢2楼回复，不过问题没解决，已上传原始档案和结果档案。希望高手帮忙感谢~~

weichenxiehou · 发表于 2013-9-18 11:52:51

回复 4# zjfy22
很适合sed解决的问题，就不必妄求批处理了。

sed -i "s/NULL\t/NULL\n/g" d:\files\*.txt

复制代码

terse · 发表于 2013-9-18 13:19:56

回复 4# zjfy22
行尾的制表符处理掉了
代码修正在2楼

zjfy22 · 发表于 2013-9-18 14:13:35

回复 2# terse

感谢！另外请教一下，如何将每列间的制表符替换成，分隔？

terse · 发表于 2013-9-18 14:17:46

本帖最后由 terse 于 2013-9-18 14:38 编辑

回复 7# zjfy22

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
set "ph=d:\file"
for /f "tokens=*" %%a in ('findstr /imc:"%tab%null" %ph%\*.txt') do (
(for /f "usebackq delims=" %%i in ("%%a") do (
set "str=%%i"
set "str=!str:%tab%=,!"
set str=!str:,null=^
!
for /f "tokens=* delims=," %%j in ("!str!") do echo %%j
))>$
move $ "%%a"
)
pause

复制代码

zjfy22 · 发表于 2013-9-18 14:55:48

回复 8# terse
谢谢，原始档案不变，现想要实现结果2 要如果修改，
我将上面的代码加入后，在换行前面会有一个逗号，

terse · 发表于 2013-9-18 15:33:37

回复 9# zjfy22

我这里怎么没有 8楼的代码

zjfy22 · 发表于 2013-9-18 15:46:48

回复 8# terse

感谢！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 批处理如何将文档中的null + 之后的制表符 替换为换行符？

[文本处理] 批处理如何将文档中的null + 之后的制表符替换为换行符？