求教如何批处理修改.ini文件中某一日期

花开花落 · 发表于 2013-8-26 10:26:06

求教如何批处理修改.ini文件中某一日期

如何通过批处理，将下面SaleNo=20130708一行中，等号后面的内容修改为当前日期，格式不变。
比如今天是2013年8月26日，等号后面的内容就修改为20130826
[system]
oilgunno=088
StationID=
SaleNo=20130708

Lumiere · 发表于 2013-8-26 12:27:34

回复 1# 花开花落
如果文本就这三行而且前面是固定的话，代码如下：

@echo off
set date=%date:/=%
echo [system]>1.ini
echo oilgunno=088>>1.ini
echo StationID=>>1.ini
echo SaleNo=%date:~0,-3%>>1.ini
pause

复制代码

DAIC · 发表于 2013-8-26 13:36:08

sed "s/SaleNo=.*/SaleNo=20130826/" a.ini > b.ini

复制代码

PowerShell · 发表于 2013-8-26 19:16:59

本帖最后由 PowerShell 于 2013-8-26 19:19 编辑

这条powershell命令，可以把“SaleNo=”为开头，后面内容任意的字符串，替换成今天内容，即你想要的

"SaleNo=2013s0708" -replace "SaleNo=.*",('SaleNo=' + (get-date -uformat %Y%m%d))

复制代码

再说一遍，第一个带引号的字符串，应该是含有【SaleNo=】，而后面任意。也就是说这样也行

"SaleNo=sdfsdkfflflccc" -replace "SaleNo=.*",('SaleNo=' + (get-date -uformat %Y%m%d))

复制代码

结果为：
SaleNo=20130826

花开花落 · 发表于 2013-8-27 21:24:29

本帖最后由花开花落于 2013-8-27 21:33 编辑

回复 2# Lumiere

文本不是就这三行，前后都有很多内容，我只想替换SaleNo= 这一行，除了这一行，整个文本没有再出现SaleNo=的字符了

也可以把SaleNo= 这一行完全删除了，重新添加，要怎么写呢？

Lumiere · 发表于 2013-8-27 23:33:36

本帖最后由 Lumiere 于 2013-8-27 23:36 编辑

回复 5# 花开花落

那在帖子一开始就说清楚撒，我不知道后面两位高手的sed命令和powersell命令能否满足你的要求，你可以试一下。下面是我的批处理代码，自己试一下看。
假设你的这个ini文件名为1.ini，将以下代码做成bat文件放在同一文件夹下。
1.如果只是需要删除那一行，其他不便的话，代码如下：

@echo off
findstr /v "SaleNo" 1.ini>>2.ini
del 1.ini&ren 2.ini 1.ini
pause

复制代码

2.如果要替换那行而不是删除的话：

@echo off
set date=%date:/=%
for /f "delims=" %%a in (1.ini) do (
echo %%a|find "SaleNo="||echo %%a>>2.ini
echo %%a|find "SaleNo="&&call echo SaleNo=%date:~0,-3%>>2.ini
)
del 1.ini&ren 2.ini 1.ini
pause

复制代码

文本名假设一样。

terse · 发表于 2013-8-28 00:29:13

本帖最后由 terse 于 2013-8-28 11:55 编辑

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=*" %%i in (a.ini) do (
set "str=%%i"
if /i "!str:~,7!" == "SaleNo=" (
echo SaleNo=%date:~,4%%date:~5,2%%date:~8,2%
) else echo !str!
))>$
move $ a.ini
pause

复制代码

Lumiere · 发表于 2013-8-28 01:54:17

回复 7# terse

我测试了以下兄台的代码好像最后在那一行多了个双引号，其他没事。想请教一下哎，那个像美元一样的符号在批处理中表示什么意思？有什么用法呢？

花开花落 · 发表于 2013-8-28 09:10:42

两位的代码我都试过了，都可以实现，确实长见识了，非常感谢，不过还有一个小问题，就是这两个批处理执行完所有的空行都没有了，这个可以处理不？

Batcher · 发表于 2013-8-28 11:12:57

回复 8# Lumiere

一个普通的临时文件的名字
如果你喜欢的话可以把它改成a.txt

terse · 发表于 2013-8-28 11:53:36

回复 9# 花开花落

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('findstr /n .* b.ini') do (
set "str=%%i"
setlocal enabledelayedexpansion
set "str=!str:*:=!"
if /i "!str:~,7!" == "SaleNo=" (
set "str=SaleNo=%date:~,4%%date:~5,2%%date:~8,2%"
)
echo;!str!
endlocal
))>$
move $ b.ini
pause

复制代码

Lumiere · 发表于 2013-8-28 11:54:06

回复 10# Batcher

就这样没有名字没有扩展名就表示临时文件么？这种临时文件与明确指明文件的名字来创建临时文件有什么内存资源占用方面的差别吗？还有其他用法么？

terse · 发表于 2013-8-28 11:55:27

回复 8# Lumiere
是的多打了一个谢提醒

花开花落 · 发表于 2013-8-28 13:44:00

本帖最后由花开花落于 2013-8-28 13:49 编辑

回复 11# terse

这次可以了，非常感谢大家，学习啦

Batcher · 发表于 2013-8-28 13:55:21

回复 12# Lumiere

效率上没有差异，可能他们觉得写成那个样子比较酷。或者写成那样不容易覆盖当前目录下的同名文件

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 求教如何批处理修改.ini文件中某一日期