批处理实现WIN7创建无线热点。虚拟WIFI(Virtual WIFI)创建。

zhouyongjun · 发表于 2013-3-7 11:31:57

让WIN7笔记本成为WIFI热点，其他设备不需要无线路由器就可以通过笔记本无线共享上网。这是WIN7提供的一个功能。由于本人比较喜欢这个功能，特写了个批处理来方便实现，并将开启开关动态添加到桌面右击菜单中，使用更加方便。相信其他朋友也会有需要，特分享给大家。

@echo off
title Win7虚拟WIFI[Z-Y-J]
::判断是否创建了虚拟WIFI，若创建了则运行删除部分，否则运行创建部分。（若注册表中无记录也将重新创建）
reg query hkcr\DesktopBackground\Shell\VirWifi >nul 2>nul && goto DelVirtualWifi || goto CreateVirtualWifi
::创建虚拟WIFI
:CreateVirtualWifi
set /p SSID=SSID（请设置无线ID）:
echo 安全密钥应为 8 到 63 个 ASCII 字符组成的字符串.
set /p PassWord=PassWord（请设置无线密码）:
::启用虚拟WIFI，密匙默认为永不过期。
netsh wlan set hostednetwork mode=allow ssid=%SSID% key=%PassWord% >nul 2>nul
echo 已经启用虚拟WIFI.
::将虚拟WIFI的状态添加到桌面快捷菜单，并关联一句复合CMD命令，让其动态改变虚拟WIFI的状态。
reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d "开启虚拟WIFI" /f >nul 2>nul
reg add hkcr\DesktopBackground\Shell\VirWifi\command /ve /t reg_sz /d "cmd /c reg query hkcr\DesktopBackground\Shell\VirWifi /ve | find """关闭虚拟WIFI""" >nul 2>nul && (netsh wlan stop hostednetwork >nul 2>nul & reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """开启虚拟WIFI""" /f >nul 2>nul) || (netsh wlan start hostednetwork >nul 2>nul & reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """关闭虚拟WIFI""" /f >nul 2>nul)" /f >nul 2>nul
::添加计划任务，系统每次开机都重新初始化虚拟WIFI的显示状态。
schtasks /create /ru system /tn RestVirWIFI /sc onstart /tr "cmd /c reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """开启虚拟WIFI""" /f >nul 2>nul" /f >nul 2>nul
echo 已将开关虚拟WIFI添加到桌面右击菜单中.
echo 虚拟WIFI创建成功！请确定已经连接到Internet的网络是否已对虚拟WIFI共享。
echo 【设置共享的方法】
echo 右击已连接到Internet的网络连接，选择“属性”→“共享”，
echo 勾上“允许其他...连接”并选择已创建好的虚拟WIFI。
echo 确定之后，提供共享的连接图标旁会出现“共享的”字样，表示已共享至虚拟WIFI。
echo 共享完成后，在桌面右击菜单中就可以选择开启或关闭虚拟WIFI了。
echo 按任意键退出！
pause >nul
goto :eof
::删除虚拟WIFI
:DelVirtualWifi
echo 确定真的要删除虚拟WIFI？按任意键继续删除，放弃请直接关闭窗口。
pause >nul
::停用虚拟WIFI
netsh wlan set hostednetwork mode=disallow >nul 2>nul
::清除注册表记录
reg delete hkcr\DesktopBackground\Shell\VirWifi /f >nul 2>nul
::删除计划任务
schtasks /delete /tn RestVirWIFI /f >nul 2>nul
echo 删除成功，按任意键退出。
pause >nul
goto :eof

复制代码

cjiabing · 发表于 2013-3-7 11:50:54

弱弱地问一句，XP的笔记本可不可以？

zhouyongjun · 发表于 2013-3-7 11:56:06

本帖最后由 zhouyongjun 于 2013-3-7 12:13 编辑

回复 2# cjiabing

XP貌似没有这个功能。
但是好像有其他方法可以连。

cjiabing · 发表于 2013-3-7 13:51:53

回复 3# zhouyongjun

网上有许多神贴说XP也可以虚拟WIFI，瞎搞了半天，手机可以收到信号，可无法连接，点解？
手机要怎么设置吗？

zhouyongjun · 发表于 2013-3-7 14:05:48

回复 4# cjiabing

网络连接设置共享了没有。如果不行桥接一下本地连接与无线连接，看看是否可以。

cjiabing · 发表于 2013-3-7 14:18:06

回复 5# zhouyongjun

都试过了，现在就是桥接。手机显示有信号，也进行静态IP设置了，信号强，点击wifi就是没有连接。

秋水 · 发表于 2013-3-7 18:04:18

这有个帖子说XP可以的、、但是要打补丁。。
好吧，下面的评论貌似都否定了。
http://www.wifigx.com/android_adhoc/index.html

111 · 发表于 2013-3-10 18:36:56

winxp也可以（不要误以为是win7，就是xp，我是仿的win7）

cjiabing · 发表于 2013-3-10 19:05:02

回复 8# 111

怎么设置XP？怎么仿W7？

111 · 发表于 2013-3-10 19:18:53

回复 9# cjiabing

先打开“查看可用的无线网络”，再点“为家庭或小型办公室设置无线网络”就可以看到刚才的图片了
仿w7用http://www.9553.com/soft/6767.htm就可以了

MCRGZN · 发表于 2015-8-13 12:57:20

6666666666

qepwq915 · 发表于 2016-11-27 15:58:34

支持看看win7的台式机是不行

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[网络工具] 批处理实现WIN7创建无线热点。虚拟WIFI(Virtual WIFI)创建。

浏览过的版块

		自动登录	找回密码
密码			注册