设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT求助&讨论 › [已解决]请问UTF-8如何批量转为ANSI？
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发新帖
查看: 40992|回复: 9

[文本处理] [已解决]请问UTF-8如何批量转为ANSI？

[复制链接]
每天几分
发表于 2012-12-1 14:18:12 | 显示全部楼层 |阅读模式
本帖最后由 每天几分 于 2012-12-2 17:31 编辑

有些txt文件混杂了UTF-8格式的，数千个文件，不知是哪一个，请问如何将同一文件夹内的UTF-8格式的文本全部转为ANSI格式？

评分

参与人数 1PB +2 收起 理由
Batcher + 2 感谢给帖子标题标注[已解决]字样

查看全部评分

回复

举报

Batcher
发表于 2012-12-1 20:39:10 | 显示全部楼层
http://www.bathome.net/thread-10861-1-1.html
http://www.bathome.net/thread-19842-1-1.html
回复

举报

每天几分
 楼主| 发表于 2012-12-1 20:55:00 | 显示全部楼层
回复 2# Batcher


    不太懂……
回复

举报

Batcher
发表于 2012-12-1 20:56:59 | 显示全部楼层
回复 3# 每天几分


    多看几遍
回复

举报

每天几分
 楼主| 发表于 2012-12-1 21:26:48 | 显示全部楼层
回复 4# Batcher


    好吧……
回复

举报

每天几分
 楼主| 发表于 2012-12-1 22:07:23 | 显示全部楼层
回复 4# Batcher

下面这个VBS可以逐个拖进转换，可以修改一下么，改成把同一文件夹里的UTF格式文件批量转为ANSI。
  1. ' *============================================================================*
  2. ' * 批量编码转换包括GB2312，UTF-8，Unicode，支持拖动，可扩展到右菜单（发送到） *
  3. ' * CodeChange.vbs     BY: yongfa365 http://www.yongfa365.com       2007-10-04 *
  4. ' * UTF82ANSI.vbs   BY: fastslz   http://bbs.cn-dos.net          2007-12-03 *
  5. ' *============================================================================*
  6. aCode = "UTF-8"
  7. bCode = "GB2312"
  8. Set objArgs = WScript.Arguments
  9. If objArgs.Count=0 Then
  10.     MsgBox "本脚本仅支持"&aCode&"到"&bCode&"的转换，请将您要转换的文件拖到这个文件上！    "&vbCrLf&"命令行用法：UTF82ANSI.vbs [驱动器][目录][文件名1][文件名2]...", vbInformation, "拖拽批量编码转换工具 BY: fastslz"
  11. End If
  12.     For I = 0 To objArgs.Count - 1
  13.         FileUrl = objArgs(I)
  14.         Call CheckCode (FileUrl)
  15.         Call WriteToFile(FileUrl, ReadFile(FileUrl, aCode), bCode)
  16.     Next
  17. Function ReadFile(FileUrl, CharSet)
  18.     Dim Str
  19.     Set stm = CreateObject("Adodb.Stream")
  20.     stm.Type = 2
  21.     stm.mode = 3
  22.     stm.charset = CharSet
  23.     stm.Open
  24.     stm.loadfromfile FileUrl
  25.     Str = stm.readtext
  26.     stm.Close
  27.     Set stm = Nothing
  28.     ReadFile = Str
  29. End Function

  31. Function WriteToFile (FileUrl, Str, CharSet)
  32.     Set stm = CreateObject("Adodb.Stream")
  33.     stm.Type = 2
  34.     stm.mode = 3
  35.     stm.charset = CharSet
  36.     stm.Open
  37.     stm.WriteText Str
  38.     stm.SaveToFile FileUrl, 2
  39.     stm.flush
  40.     stm.Close
  41.     Set stm = Nothing
  42. End Function

  44. Function CheckCode (FileUrl)
  45.     Dim slz
  46.     set slz = CreateObject("Adodb.Stream")
  47.     slz.Type = 1
  48.     slz.Mode = 3
  49.     slz.Open
  50.     slz.Position = 0
  51.     slz.Loadfromfile FileUrl
  52.     Bin=slz.read(2)
  53.     if AscB(MidB(Bin,1,1))=&HEF and AscB(MidB(Bin,2,1))=&HBB Then
  54.        Codes="UTF-8"
  55.        elseif AscB(MidB(Bin,1,1))=&HFF and AscB(MidB(Bin,2,1))=&HFE Then
  56.               Codes="Unicode"
  57.               else
  58.               Codes="GB2312"
  59.     end if
  60.     if not aCode = Codes Then
  61.            MsgBox "待处理文件 “"&FileUrl&"”"&vbCrLf&"该文件原始编码不是"&aCode&"，本脚本仅支持"&aCode&"到"&bCode&"的转换！    ",vbInformation,"错误终止"
  62.            WScript.Quit
  63.     end if
  64.     slz.Close
  65.     set slz = Nothing
  66. End Function
复制代码
回复

举报

Batcher
发表于 2012-12-1 22:28:28 | 显示全部楼层
回复 6# 每天几分


    到VBS版块发个帖子问问吧
回复

举报

每天几分
 楼主| 发表于 2012-12-1 22:35:20 | 显示全部楼层
回复 7# Batcher


    好吧，再等等，没人回复的话我再到VBS板块问问……
回复

举报

apang
发表于 2012-12-2 16:00:32 | 显示全部楼层
  1. aCode = "UTF-8"
  2. bCode = "GB2312"
  3. Set FSO = CreateObject("Scripting.FileSystemObject")
  4. For Each FileUrl In FSO.GetFolder(".").Files
  5.    Ext = FSO.GetExtensionName(FileUrl)
  6.    If Lcase(Ext) = "txt" Then
  7.       If CheckCode(FileUrl) Or is_valid_utf8(read(FileUrl)) Then
  8.          Call WriteToFile(FileUrl, ReadFile(FileUrl, aCode), bCode)
  9.       End If
  10.    End If
  11. Next
  12. MsgBox "OK"

  14. Function ReadFile(FileUrl, CharSet)
  15.    Dim Str
  16.    Set stm = CreateObject("Adodb.Stream")
  17.    stm.Type = 2
  18.    stm.mode = 3
  19.    stm.charset = CharSet
  20.    stm.Open
  21.    stm.loadfromfile FileUrl
  22.    Str = stm.readtext
  23.    stm.Close
  24.    Set stm = Nothing
  25.    ReadFile = Str
  26. End Function

  28. Function WriteToFile (FileUrl, Str, CharSet)
  29.    Set stm = CreateObject("Adodb.Stream")
  30.    stm.Type = 2
  31.    stm.mode = 3
  32.    stm.charset = CharSet
  33.    stm.Open
  34.    stm.WriteText Str
  35.    stm.SaveToFile FileUrl, 2
  36.    stm.flush
  37.    stm.Close
  38.    Set stm = Nothing
  39. End Function

  41. Function CheckCode (FileUrl)
  42.    Dim slz
  43.    Set slz = CreateObject("Adodb.Stream")
  44.    slz.Type = 1
  45.    slz.Mode = 3
  46.    slz.Open
  47.    slz.Position = 0
  48.    slz.Loadfromfile FileUrl
  49.    Bin=slz.read(2)
  50.    If AscB(MidB(Bin,1,1))=&HEF and AscB(MidB(Bin,2,1))=&HBB Then
  51.       CheckCode = True
  52.    end if
  53.    slz.Close
  54.    Set slz = Nothing
  55. End Function

  57. Function read(path)
  58.    Dim ado, a(), i, n
  59.    Set ado = CreateObject("ADODB.Stream")
  60.    ado.Type = 1 : ado.Open
  61.    ado.LoadFromFile path
  62.    n = ado.Size - 1
  63.    ReDim a(n)
  64.    For i = 0 To n
  65.       a(i) = ChrW(AscB(ado.Read(1)))
  66.    Next
  67.    read = Join(a, "")
  68. End Function

  70. Function is_valid_utf8(ByRef input) 'ByRef以提高效率
  71.    Dim s, re
  72.    Set re = New Regexp
  73.    s = "[\xC0-\xDF]([^\x80-\xBF]|$)"
  74.    s = s & "|[\xE0-\xEF].{0,1}([^\x80-\xBF]|$)"
  75.    s = s & "|[\xF0-\xF7].{0,2}([^\x80-\xBF]|$)"
  76.    s = s & "|[\xF8-\xFB].{0,3}([^\x80-\xBF]|$)"
  77.    s = s & "|[\xFC-\xFD].{0,4}([^\x80-\xBF]|$)"
  78.    s = s & "|[\xFE-\xFE].{0,5}([^\x80-\xBF]|$)"
  79.    s = s & "|[\x00-\x7F][\x80-\xBF]"
  80.    s = s & "|[\xC0-\xDF].[\x80-\xBF]"
  81.    s = s & "|[\xE0-\xEF]..[\x80-\xBF]"
  82.    s = s & "|[\xF0-\xF7]...[\x80-\xBF]"
  83.    s = s & "|[\xF8-\xFB]....[\x80-\xBF]"
  84.    s = s & "|[\xFC-\xFD].....[\x80-\xBF]"
  85.    s = s & "|[\xFE-\xFE]......[\x80-\xBF]"
  86.    s = s & "|^[\x80-\xBF]"
  87.    re.Pattern = s
  88.    is_valid_utf8 = (Not re.Test(input))
  89. End Function
复制代码
无BOM头的UTF-8文件判断用的是：
http://demon.tw/programming/vbs-validate-utf8.html

评分

参与人数 1技术 +1 收起 理由
每天几分 + 1 多谢！辛苦了！

查看全部评分

回复

举报

ly88888
发表于 2019-12-17 10:37:44 | 显示全部楼层
本帖最后由 ly88888 于 2019-12-17 11:57 编辑

回复 9# apang


   完美
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-19 13:31 , Processed in 0.028949 second(s), 8 queries , File On.

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表