[已解决]批处理备份前一天的日志

yang1109 · 发表于 2012-6-1 10:41:25

本帖最后由 yang1109 于 2012-6-1 13:54 编辑

各们大虾们　我是一菜鸟　帮个忙　
我想每天下午四点半定时压缩前一天生成的log文件　但是每天生成的log文件有多个　并把压缩的.zar文件放在log文件的上级目录中压缩的路劲为：
例如 D：\hi\log\*20120531*.log 成生在Ｄ：\hi下　20120531.rar （压缩的文件名也为前一天的日期）　

比如今天是2012.06.01号　前一天生成的日志有*20120531*.log *20120531*.sec *20120531*.per *20120531*.txt 等　我想把压缩的文件名为20120531.rar 注意每在生成的日志文件名里面有前一天日期但是日期有时前后会的别的字符如：request_20120531null.log
　　　十分感谢各位的帮助，谢谢

neorobin · 发表于 2012-6-1 12:25:46

本帖最后由 neorobin 于 2012-6-1 12:50 编辑

将下面代码保存为批处理文件, 然后在计划任务中加入这个批处理文件的任务, 每天 16:30 执行一次

@echo off & setlocal enabledelayedexpansion
set "workDir=D:\hi" & rem 工作目录路径, 路径不要用双引号括起
set rar="%ProgramFiles%\WINRAR\rar.exe"& rem winrar 控制台版本的路径, 若非如此, 请作修改
call :yesterday yesterday
cd /d "%workDir%"
%rar% a %yesterday%.rar "log\*%yesterday%*.*"
exit
:yesterday
for /f "tokens=2*" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate^|find/i"sSh"') do (
>nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "yyyyMMdd" /f
set /a "y=!date:~0,4!,m=1!date:~4,2!-100,d=1!date:~-2!-101"
setlocal disabledelayedexpansion
set /a "m-=!d,y-=!m,d+=!d*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"
set /a "m+=100,d+=100"
>nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "%%~b" /f
)
endlocal & set "%1=%y%%m:~-2%%d:~-2%" & exit /b

复制代码

yang1109 · 发表于 2012-6-1 13:30:35

回复 2# neorobin

高人呀你这个还没有达到我想要的效果呀这个只能打包文件名为20120531日期的数据如果在文件名里面在加点request_20120531_112.log就不行这个包就被忽略了还忘高人在指点呀

neorobin · 发表于 2012-6-1 13:42:33

回复 3# yang1109

测试过可以的, 代码中的通配形式, 就是你要求的 *%yesterday%*.*

yang1109 · 发表于 2012-6-1 13:50:10

回复 4# neorobin

嗯我刚又看了下刚刚 *%yesterday%*.* 前面我打成？去了高人谢了哈非常感谢

yang1109 · 发表于 2012-6-1 13:52:24

回复 5# yang1109

对了我觉得这个好复杂哟能不能在这个程序上改下我自已也成了但不成功
@echo off
set "i=%date:~,4%%date:~5,2%%date:~8,2%"
set "d=i-1"
pushd "d:\hi\log"
"%programfiles%\winrar\rar.exe" a -o+ -ep "..\%d%.rar" "%d%.*"

pause

neorobin · 发表于 2012-6-1 13:58:27

本帖最后由 neorobin 于 2012-6-1 14:01 编辑

回复 6# yang1109

纯粹依靠 cmd 来计算昨天的日期, 没有简单的代码,  子程序采用了注册表读取和设置日期格式的方式, 确实显繁琐了, 好处是适应各种原始的日期格式, 而你示出的代码是要求工作在特定的日期格式条件下的

  set /a "y=!date:~0,4!,m=1!date:~4,2!-100,d=1!date:~-2!-101"
  set /a "m-=!d,y-=!m,d+=!d*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"

这里的算法: 日数减1, 如果成了0, 月数减1, 如果月数成了0, 年数减1; 如果日数成了0, 根据当前年月(大小月, 2月的平闰情况)确定日数, 如果月数成了0, 变成12, 否则不变

yang1109 · 发表于 2012-6-1 15:07:55

回复 7# neorobin

哦学到了高人谢了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理备份前一天的日志

评分

评分

[文本处理] [已解决]批处理 备份前一天的日志

评分

评分

[文本处理] [已解决]批处理备份前一天的日志