[已解决]批处理怎么删除不同文件夹中的文本文件中的#连同#之内的字符与文本#？

terse

也来个纯P，尽量处理特殊字符吧

1. 
   
2. @echo off
   
3. for /f "delims=" %%f in ('dir/b/s/a-d *.txt') do (
   
4.      (for /f "usebackq tokens=1* delims=#" %%i in ("%%f") do (
   
5.            set "str=%%i"
   
6.            set "s=%%j"
   
7.            if "%%j" neq "" (
   
8.                call :loop
   
9.                setlocal enabledelayedexpansion
   
10.                echo !str!
    
11.                endlocal
    
12.           ) else echo %%i
    
13.      ))>"New_%%~nf.tx"
    
14. )
    
15. pause
    
16. exit
    
17. :loop
    
18. if "%s%" == ""  goto :eof
    
19. for /f "tokens=2* delims=#" %%i in ("%s%") do (
    
20.      set "t=%%i"
    
21.      set "s=%%j"
    
22.      setlocal enabledelayedexpansion
    
23.      if "!t: =!" neq "" set "str=!str!!t!"
    
24.      for /f "delims=" %%a in ("!str!") do endlocal&set "str=%%a"
    
25.      call :loop
    
26. )
    

复制代码

第三方gawk 处理子目录 要加FOR

1. gawk "{gsub(/#[^#]*#/, ""); print >>FILENAME"NEW_tx"}" *.txt

复制代码

aloha20200628

订正了15楼代码。其中jscript和python脚本因均以文件而非行作为处理单位，故可有效解析定界符内容被断行的情况。

Five66

来个偷懒的，保存为ansi编码的bat
仅处理当前路径中文件夹里的文本文件
要求文本文件编码为gbk，文件名不要有英文百分号或936代码页无法显示的字符，还有文本中如果包含^可能会被吞
改了下，已最大程度支持特殊字符（大概）

1. 
   
2. @echo off&chcp 936 >nul
   
3. 
   
4. for /d %%a in (*) do (
   
5. for /f "delims=" %%b in ('dir /b /s /a-d "%%a\*.txt"') do (
   
6. setlocal
   
7. for /f "delims=" %%c in ('findstr /n .* "%%b"') do (
   
8. set "line=%%c"
   
9. setlocal enabledelayedexpansion
   
10. if "!line:*:=!" == "" (endlocal&echo,) else (
    
11. set "line=!line:*:=!"
    
12. for /f "delims=" %%i in ("$!line:#=^#!") do endlocal&set "line=%%i"
    
13. set o=
    
14. call :aaa
    
15. )
    
16. )
    
17. endlocal
    
18. )>"%%~dpb_new_%%~nxb"
    
19. )
    
20. pause&exit/b
    
21. 
    
22. :aaa
    
23. setlocal enabledelayedexpansion
    
24. set "line=!line:~1!"
    
25. for /f "tokens=1* delims=^" %%x in ("$!line!") do (
    
26. endlocal&set line=&set "tk1=%%x"&set "tk2=%%y"
    
27. )
    
28. setlocal enabledelayedexpansion
    
29. set "tk1=!tk1:~1!"
    
30. if "!tk1:~0,1!" == "#" (
    
31. if "!tk2:~0,1!" == "#" (set "line=!tk2:~1!") else set "o=!o!!tk1!"&set "line=!tk2!"
    
32. ) else (
    
33. set "o=!o!!tk1!"
    
34. set "line=!tk2!"
    
35. )
    
36. if defined line (
    
37. for /f "delims=" %%i in ("$!line!") do (
    
38. for /f "delims=" %%j in (""!o!"") do endlocal&set "line=%%i"&set "o=%%~j"
    
39. )
    
40. goto :aaa
    
41. ) else echo,!o!&endlocal
    
42. goto :eof
    

复制代码

aloha20200628

一楼示例中没有那些 ^&!%()<\|/> 等特殊字符作祟，故15楼的纯P代码可以应付，当然 jscript/python/sed 等解决方案可以对此无惧。
若真要考虑纯P解法能处理上述特殊字符，还须订正其中的代码(包括字符串长度获取函数)如下》

按一楼示例原意顺便改写一个包含特殊字符的测试样本 test.txt：
'~^&!%(#将被删除#)<\|/>
'~^&!%()<\|/>#将被删除#
#将被删除#'~^&!%()<\|/>

1. 
   
2. @echo off
   
3. for /f "delims=" %%F in ('dir/b/s/a-d *.txt') do (
   
4.         (for /f "usebackq delims=" %%s in ("%%~F") do (
   
5.                 set s=%%~s
   
6.                 setlocal enabledelayedexpansion
   
7.                 set "cut=-1" &set "_s=" &(call :_strLen s sL)
   
8.                 for /L %%i in (0,1,!sL!) do (
   
9.                         set "c=!s:~%%i,1!"
   
10.                         if "!c!" neq "#" (if !cut! equ -1 set "_s=!_s!!c!") else (set/a "cut=0-!cut!")
    
11.                 )
    
12.                 (echo,!_s!)
    
13.                 endlocal
    
14.         ))>"%%~F.new"
    
15. )
    
16. endlocal &exit/b
    
17. 
    
18. :_strLen //获取字符串长度(须先开启变量延迟可保全^!等特殊字符) %1=被测字符串变量名 %2=返回值变量名
    
19.         set "_str=_!%~1!" &set "Len=0"
    
20.         for %%n in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    
21.                 if "!_str:~%%n,1!" neq "" (set/a "Len+=%%n"&set "_str=!_str:~%%n!")
    
22.         )
    
23.         set/a "%~2=!Len!-1" &exit/b
    

复制代码