请问批处理如何根据部分文件名新建文件夹

惆怅而又凄凉

有一堆文件混在一起了，文件名分别是：
dddd-123.zip
zzzzzzz-123.zip
aaa-123.zip

我希望能够先获取文件名到变量，然后将变量的-符号作为截取位置，将前面的字符作为文件夹名称，在别处新建，然后将对应的文件移动过去。

没想明白应该怎么解决前2步。

特此求教。

Batcher

回复 1# 惆怅而又凄凉


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "tokens=1* delims=-" %%a in ('dir /b /a-d *.zip') do (
   
4.     echo 正在处理文件：%%a
   
5.     if not exist "%%a" (
   
6.         md "%%a"
   
7.     )
   
8.     move "%%a-%%b" "%%a"
   
9. )

复制代码

惆怅而又凄凉

回复 2# Batcher


    感谢解答，我的主要问题是：
假设文件名是32132-aadjoig.zip

我本来考虑的是
1、遍历文件名，将文件名写入变量。
2、将变量字符串从“-”前面截取。
3、在指定位置建立文件夹为变量。
4、将该文件移至该文件夹。

但我没找到字符串按关键字截取的命令，还望再指教一二，谢谢！

Batcher

回复 3# 惆怅而又凄凉

1. @echo off
   
2. cd /d "%~dp0"
   
3. for %%a in (*.zip) do (
   
4.     echo 正在处理文件：%%a
   
5.     set "FileName=%%a"
   
6.     set "NameRight=!FileName:*-=!"
   
7.     call set "NameLeft=%%FileName:-!NameRight!=%%"
   
8.     if not exist "!NameLeft!" (
   
9.         md "!NameLeft!"
   
10.     )
    
11.     move "%%a" "!NameLeft!"
    
12. )

复制代码

惆怅而又凄凉

回复  惆怅而又凄凉
Batcher 发表于 2023-3-8 09:23

    非常感谢解答！真的是醍醐灌顶。。。

看是看懂了，但不知道为啥出错，然后我做了中断和echo，结果是空的

1. 
   
2. cd /d "%~dp0"
   
3. for %%a in (*.jpg) do (
   
4.     echo 正在处理文件：%%a
   
5.     set "FN=%%a"
   
6.     set "FNR=!FN:*-=!"
   
7.     call set "FNL=%%FN:-!FNR!=%%"
   
8.     echo name = %%a
   
9.     echo fn = %FN%
   
10.     echo fnr = %FNR%
    
11.     echo fnl = %FNL%
    
12. pause
    
13. )
    

复制代码

1. 
   
2. 正在处理文件：a-123456.jpg
   
3. name = a-123456.jpg
   
4. fn =
   
5. fnr =
   
6. fnl =
   
7. 请按任意键继续. . .
   

复制代码

77七

回复 5# 惆怅而又凄凉


   在代码的开头加一句

1. setlocal enabledelayedexpansion

复制代码

文件名含 感叹号就在 for语句内加

1. cd /d "%~dp0"
   
2. for %%a in (*.jpg) do (
   
3.     echo 正在处理文件：%%a
   
4.     set "FN=%%a"
   
5.     setlocal enabledelayedexpansion
   
6.     set "FNR=!FN:*-=!"
   
7.     call set "FNL=%%FN:-!FNR!=%%"
   
8.     echo name = %%a
   
9.     echo fn = !FN!
   
10.     echo fnr = !FNR!
    
11.     echo fnl = !FNL!
    
12.     endlocal
    
13.     pause
    
14. )

复制代码

惆怅而又凄凉

回复  惆怅而又凄凉


   在代码的开头加一句文件名含 感叹号就在 for语句内加
77七 发表于 2023-3-8 12:16

    也试过了，不是这个原因。

Batcher

回复 7# 惆怅而又凄凉


请参考Q-13：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

77七

回复 7# 惆怅而又凄凉


   请直接复制6楼我帮你修改的代码，我测试是正常的

惆怅而又凄凉

回复  惆怅而又凄凉


   请直接复制6楼我帮你修改的代码，我测试是正常的
77七 发表于 2023-3-8 13:15

    真的耶。。。
问题不单单是延迟变量，还有变量符号，如果是叹号就正常了。

非常感谢！

惆怅而又凄凉

回复  惆怅而又凄凉


请参考Q-13：
Batcher 发表于 2023-3-8 13:07

谢谢！搞定啦！
真的不是这个空格问题。。。
我去掉空格还是空值。

是延迟变量和变量符号问题。

terse

for /f 完全可以搞定的东西 为什么要变量去变来变去呢

惆怅而又凄凉

回复 12# terse


    那还请举个例子解答一下？

terse

回复 13# 惆怅而又凄凉
二楼 B大的不能用吗
这个显示和六楼的一样效果吧

1. @echo off
   
2. for /f "tokens=1* delims=-" %%a in ('dir /b /a-d *-*.jpg') do (
   
3.     echo 正在处理文件 %%a-%%b
   
4.     echo name %%a-%%b
   
5.     echo fn %%a-%%b
   
6.     echo fnr %%b
   
7.     echo fn1 %%a
   
8. )
   
9. pause

复制代码

惆怅而又凄凉

回复 14# terse


主要我是想学习一下这个左右截取的问题，自己写了半天没折腾出来。

然后你们这套运行起来并不正常，在30万个文件的文件夹里，会一直保持黑屏，直到遍历完全部文件，再一次性处理，但这个过程并不会发生，因为达到一定数量后就直接退出了。
所以我试过运行后黑屏10秒，然后按ctrl+c，再输入N，打断遍历，就会跑掉这10秒遍历的文件。

但是后面这个答案也有个问题，因为变量延迟可能是，每次跑一百万文件后，内存占用超过20G，速度也会下降的很厉害。
所以我理解的就是前者和后者都会因为文件数量太大，导致内存占用过高，但前者是遍历完才操作，后者是遍历中操作。
因此前者无法正常工作，后者工作基本正常，堪用。

所以，后面的那个答案，更符合实际情况。
后来那个方案，昨晚已经跑掉200万文件了，还剩900万。
没出错。