【已解决】统计每个TXT文件中【<img】出现的次数，将其加入到每个文件名中。

chable · 发表于 2020-10-30 14:21:53

统计每个TXT文件中【<img】出现的次数，将其加入到每个文件名中。

同一文件夹下有X个子文件夹，每个子文件夹里都有一些TXT文件，都是UTF-8编码。

需求总述：
批量统计文件夹及子文件夹里的每个TXT文件中【<img】出现的次数，将这个数量加入到每个文件名中。

比如：
【郑板桥草书字帖一幅.TXT】这个文件中【<img】这串代码出现了19次，则将文件名改为【郑板桥草书字帖一幅（共19张图片）.TXT】

测试文件见附件

报酬：5元（以最早实现为准）

目前状态：已经解决

zaqmlp · 发表于 2020-10-30 14:37:59

5元？？？这就很尴尬了

qixiaobin0715 · 发表于 2020-10-30 15:17:30

本帖最后由 qixiaobin0715 于 2020-10-30 15:36 编辑

好像不行，统计的只是img出现的行数，不是img的数量

@echo off
for /r %%i in ("*.txt") do (
for /f %%a in ('type "%%i"^|find /c "<img"') do (
ren "%%i" "%%~ni（共%%a张图片）.txt"
)
)
pause&exit

复制代码

chable · 发表于 2020-10-30 16:50:17

回复 3# qixiaobin0715

统计出来的数目不对。测试了一下，正确应该是4、45.您的代码结果是3、23

WHY · 发表于 2020-10-30 19:05:23

本帖最后由 WHY 于 2020-10-31 00:06 编辑

@echo off
PowerShell "dir . -Filter *.txt -Recurse | forEach{$str=[IO.File]::ReadAllText($_.FullName); $n=($str -split '<img').Count-1; ren $_.FullName -NewName($_.BaseName + '（' + $n + '）' + $_.Extension) -WhatIf}"
pause

复制代码

Batcher · 发表于 2020-10-31 12:49:40

回复 1# chable

BAT调用grep.exe命令行工具
http://bcn.bathome.net/s/tool/index.html?key=grep

@echo off
setlocal enabledelayedexpansion
set "SrcFolder=D:\Test\测试文件"
if not exist "%SrcFolder%" (
goto :eof
) else (
cd /d "%SrcFolder%"
)
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
for /f "delims=" %%b in ('grep -o "<img" "%%a" ^| find /c /v ""') do (
ren "%%a" "%%~na（共%%b张图片）%%~xa"
)
)

复制代码

小渣飞 · 发表于 2020-11-1 00:26:48

本帖最后由小渣飞于 2020-11-1 00:31 编辑

大佬这里的goto :eof是去哪，没看到 call 呀

chable · 发表于 2020-11-1 09:45:50

回复 5# WHY

好像统计到了数目了，但是没有最后执行重命名的动作。

chable · 发表于 2020-11-1 09:50:12

回复 6# Batcher

下载了GREP.EXE后，要放到哪个文件里？

chable · 发表于 2020-11-1 09:52:59

回复 6# Batcher

我下载了2.21 grep.exe 。放到C:\WINDOWS下，运行完后，都只能统计到1张图片。功有已经用其他的代码实现了，感谢您！

Batcher · 发表于 2020-11-1 21:29:26

回复 10# chable

我这边测试 grep 3.0 没有问题

WHY · 发表于 2020-11-2 00:01:22

@if (0)==(0) echo off
for /f "tokens=1*" %%i in ('dir /b /a-d /s *.txt ^| cscript //nologo //e:jscript "%~f0"') do (
echo ren "%%j" "%%~nj（%%i）%%~xj"
)
pause & exit
@end
function getStrNumber(file){
var ado = new ActiveXObject('ADODB.Stream');
ado.Type = 2;
ado.Mode = 3;
ado.Charset = 'utf-8';
ado.Open();
ado.LoadFromFile(file);
return ado.ReadText(-1).split('<img').length - 1;
}
while(!WSH.StdIn.AtEndOfStream){
var f = WSH.StdIn.ReadLine();
WSH.Echo('' + getStrNumber(f) + ' ' + f);
}

复制代码

WHY · 发表于 2020-11-2 00:04:00

本帖最后由 WHY 于 2020-11-2 00:18 编辑

GNU sed 4.3

@echo off
for /f "delims=" %%i in ('dir /b /a-d /s *.txt') do (
for /f %%j in ('sed "s/<img/\n&/g" "%%i" ^| find /c "<img"') do (
echo ren "%%i" "%%~ni（%%j）%%~xi"
)
)
pause

复制代码

三十年前 · 发表于 2020-11-3 11:06:09

回复 13# WHY

哥，你这代码有问题，第三段中间的 sed 应该是 set 吧？
我改过来后发现运行还是有问题。

qixiaobin0715 · 发表于 2020-11-3 15:31:15

纯批好像也能解决：

@echo off
setlocal enabledelayedexpansion
for /r %%i in ("*.txt") do (
set n=0
for /f "delims=" %%a in ('type "%%i"') do (
set str=%%a
set "str=!str:img alt= <img alt!"
for %%k in (!str!) do (
set var=%%k
if not "!var!"=="!var:<img=!" set /a n+=1
)
)
ren "%%i" "%%~ni（共!n!张图片）%%~xi"
)
pause&exit

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】统计每个TXT文件中【<img】出现的次数，将其加入到每个文件名中。