【练习】批处理显示文本中8字节的行

随风

在百度贴吧看到一题，出给大家练练手。
那儿有一仙说他们老大不加思索就作出来了，（本人足足想了10分钟才有完整思路）实在对这位老大佩服的很，可惜未见到代码 (^_^)
题：
要求显示a.txt中8字节的行，注意有特殊字符 ^%&<!>等。
增加要求为：不创建临时文件，不使用第三方工具。
注意：说的是字节而不是字符，需考虑到多种情况，比如冒号、分号开头的行。。。




.

zqz0012005

我首先想到的思路是：for /f 解析 findstr /o 做减法

batman

小水一个：不创建临时文件就确实加大了难度了，呵呵，看看大家的思路吧。。。

netbenton

抛砖引玉

1. @echo off
   
2. for /f "delims=" %%a in (%~0) do (
   
3.     set str=%%a
   
4.     setlocal enabledelayedexpansion
   
5.     if "!str:~8!" equ "" (
   
6.         for /l %%b in (0,1,7) do (
   
7.                 if "!str:~%%b,1!" neq "" (
   
8.                         if "!str:~%%b,1!0" gtr "z" (set/a len+=2) else (set/a len+=1)
   
9.                                         rem     ^ 这个字符用小于最小全角字符的即可，这知是不是z
   
10.                 )
    
11.         )
    
12.     )
    
13.     if !len! equ 8 echo;!str!
    
14. 
    
15.     endlocal
    
16. 
    
17. )
    
18. pause
    
19. rem 后面的是例子
    
20. :2345678
    
21. ::批处理
    
22. ::!!!!!!
    
23. ::^"!!|>
    
24. ::物><!%
    
25. :23456789
    
26. ::批处理1
    
27. ::!!!!!!1
    
28. ::^"!!|>1
    
29. ::物><!%1

复制代码

随风

先忽略8个字符以上的行，再逐字判断，不错，但若需显示的行不是8字节而是更大点的数，效率会同时降低，且未考虑分号开头的行和含全角空格的行。
先加5分，后面的继续。。。

[ 本帖最后由 随风 于 2009-6-10 19:19 编辑 ]

netbenton

解决分号问题了

1. @echo off
   
2. for /f "tokens=* delims=;" %%a in ('findstr /n .* %0') do (
   
3.     set str=%%a
   
4.     setlocal enabledelayedexpansion
   
5.     set "str=!str:*:=!"
   
6.     if "!str:~8!" equ "" (
   
7.         for /l %%b in (0,1,7) do (
   
8.                 if "!str:~%%b,1!" neq "" (
   
9.                         if "!str:~%%b,1!0" gtr "z" (set/a len+=2) else (set/a len+=1)
   
10.                                         rem     ^ 这个字符用小于最小全角字符的即可，这知是不是z
    
11.                 )
    
12.         )
    
13.     )
    
14.     if !len! equ 8 echo;!str!
    
15. 
    
16.     endlocal
    
17. 
    
18. )
    
19. pause
    
20. rem 后面的是例子
    
21. :2345678
    
22. ::批处理
    
23. ::!!!!!!
    
24. ::^"!!|>
    
25. ::物><!%
    
26. :23456789
    
27. ::批处理1
    
28. ::!!!!!!1
    
29. ::^"!!|>1
    
30. ::物><!%1
    
31. ;ddddddd

复制代码

随风

全角空格呢？   (^_^)

zqz0012005

考虑到所有特殊字符的情况后，2楼说的方法实现起来还真有点麻烦。
先来个代码简单但效率超低的方法

1. @echo off
   
2. set var2=.
   
3. for /f "usebackq delims=" %%a in ("%~f0") do (
   
4.     set var=%%a
   
5.     set var|findstr /o ".*"|findstr /b "14:" >nul && (
   
6.         setlocal enabledelayedExpansion
   
7.         echo !var!
   
8.         endlocal
   
9.     )
   
10. )
    
11. pause&exit/b
    
12. 
    
13. :2345678
    
14. ^%;　<!"
    
15. 上面是全角空格

复制代码

随风

效率是够低的，也每考虑分号开头的行 (^_^)

netbenton

高效的，可处理绝大部分字符

1. @echo off
   
2. for /f "tokens=*" %%a in ('^(type %0^&echo.^)^|findstr /o .*') do (
   
3.     set str=%%a
   
4.     setlocal enabledelayedexpansion
   
5.     for /f "delims=:" %%b in ("!str!") do (
   
6.                 set/a len=%%b-up-2
   
7.                 if !len! equ 8 echo !ech!
   
8.                     set "ech="
   
9.                 for %%c in ("!str:*:=!") do (
   
10.                         endlocal&set up=%%b&set ech=%%~c
    
11.     ))
    
12. 
    
13. )
    
14. pause
    
15. rem 后面的是例子
    
16. :2345678
    
17. ::批处理
    
18. ::!!!!!!
    
19. ::^"!!|>
    
20. ::物><!%
    
21. :23456789
    
22. ::批处理1
    
23. ::!!!!!!1
    
24. ::^"!!|>1
    
25. ::物><!%1
    
26. ;ddddddd

复制代码

zqz0012005

2楼的方法其实不麻烦，开始没想清楚，变量还是可以保留的

1. @echo off
   
2. for /f "tokens=1* delims=:" %%a in ('findstr /n /o .* "%~f0"') do (
   
3.     for /f "delims=:" %%i in ("%%b") do set m=%%i
   
4.     set /a x=m-n
   
5.     setlocal enabledelayedExpansion
   
6.     if !x!==10 echo !var:*:=!
   
7.     endlocal
   
8.     set /a n=m
   
9.     set var=%%b
   
10. )
    
11. pause&exit/b
    
12. 
    
13. ;2345678
    
14. ^%;　<!"
    
15. 上面是全角空格

复制代码

zqz0012005

晕，findstr /n 写习惯了，%%a根本没用到~~
for /f "delims=" %%a in ('findstr /o .* "%~f0"') do


方法都一样，被netbenton兄抢先了，而且考虑到了最后一行没有回车的情况。
"tokens=*"改成"delims="就兼容所有字符了。
可以用more "%~f0"|findstr /o .*更简洁点，more会在文本内容后面加额外的回车。

[ 本帖最后由 zqz0012005 于 2009-6-10 20:57 编辑 ]

netbenton

re zqz0012005
我正找了半天，怎么解最后一行不是空格的问题呢！
原来用more可以自动加空行呀，太好了！
完美代码如下：

1. @echo off
   
2. for /f "tokens=*" %%a in ('^(more %0 ^&echo aa^)^|findstr /o .*') do (
   
3.     set str=%%a
   
4.     setlocal enabledelayedexpansion
   
5.     for /f "delims=:" %%b in ("!str!") do (
   
6.         set/a len=%%b-up-2
   
7.         if !len! equ 8 echo !ech:*:=!
   
8.         endlocal&set/a up=%%b
   
9.     )
   
10.     set ech=%%a
    
11. )
    
12. pause
    
13. rem 后面的是例子
    
14. :2345678
    
15. ::批处理
    
16. ::!!!!!!
    
17. ::^"!!|>
    
18. ::物><!%
    
19. :23456789
    
20. ::批处理1
    
21. ::!!!!!!1
    
22. ::^"!!|>1
    
23. ::物><!%1
    
24. ;ddddddd
    
25. ^%;　<!"

复制代码

随风

zqz 真是一语点醒梦中人，代码早以写好，就是解决不了最后一行没有回车的问题。老是用type
最终大家的思路都到一起来了 (^_^)
代码如下：

1. @echo off&set /a h=0
   
2. for /f "delims=" %%a in ('^(more %~s0^&echo.^)^|findstr /o .*') do (
   
3.    for /f "delims=:" %%i in ("%%a") do set /a n=%%i-2-h,h=%%i
   
4.    setlocal enabledelayedexpansion
   
5.    if !N! equ 8 echo;【!var:*:=!】
   
6.    endlocal
   
7.    set "var=%%a"
   
8. )
   
9. pause&exit
   
10. 
    
11. 下面是分号开头的行
    
12. ;1234567
    
13. 下面是8个空格
    
14.         
    
15. 下面是冒号开头的行
    
16. ::::::::
    
17. 下面是特殊字符的行
    
18. %^&*<">!
    
19. 下面是含全角空格的行
    
20. 　　　78
    
21. 下面是全角半角混合的行
    
22. 壹23肆78
    
23. 下面是纯半角字符的行
    
24. 12345678

复制代码

zqz0012005

忘了，最后还要自己加一行，以应付最后一行也是8个字节的情况。