[已解决]批处理如何查找出文本中字符数最多的行/字符串长度最长的行

慕夜蓝化

BAT如何找出文本最大行？
有一小说文本开头部分:

1. 
   
2. 　　文本豪客 [url]www.txt.hk[/url] 〓 [url]www.bbzw.net[/url] 拜拜中文
   
3. 
   
4. 　　作品：堕落血天使
   
5. 
   
6. 　　作者：天龙怒吟
   
7. 
   
8. 　　男主角：楚明
   
9. 
   
10. 　　内容简介：
    
11. 
    
12. 　　堕落血天使，是天龙怒吟写的一部西方奇幻小说，主要讲述的是一个中国小鬼学了一身杂七杂八的武功，把各种西方大神揍的满头是包的故事。
    
13. 
    
14. 　　正文
    
15. 
    
16. 　　背景设定
    
17. 
    
18. 　　天使等级的划分
    

复制代码

要求：
在批处理窗口中直接显示字数最长的行。
比如这一行：

1. 
   
2. 堕落血天使，是天龙怒吟写的一部西方奇幻小说，主要讲述的是一个中国小鬼学了一身杂七杂八的武功，把各种西方大神揍的满头是包的故事。
   

复制代码

若具有相同字数的最大行，则全部显示。
比如这两行：

1. 
   
2. 　　首先，在没有形成整个世界的时候，创世之神，生命之神，破灭之神从混沌开始初生，三位大神并称为第一代神，也就是最原始的神。
   
3. 　　我们不能说毁灭就是邪恶的，因为，如果没有毁灭，也就没有了创造的意义，就正如没有生命的死亡，这个世界将无限的堆满了人群。
   

复制代码

求解。

cobat

看11楼和19楼

pcl_test

回复 1# 慕夜蓝化
一般思路，逐行读取逐行统计字符数，并在每行标记上字符数（可用变量存储也可导出到临时文件），以标记的字符数进行排序取得最大值，用findstr "最大值" "文本"获得所有字符数最多的行
求字符串长度方法
http://www.bathome.net/viewthread.php?tid=11799

慕夜蓝化

回复 3# pcl_test

嗯嗯，我去看一下。
主要速度快就成。

pcl_test

回复 4# 慕夜蓝化
另一种思路，先set max=0，逐行读取逐行统计字符数并标记好字符数，同时以辗转比较和赋值max的方式获取到最大值（如第一行字符数为23，23比max初值大，set max=23，第二行字符数为11，比max小，忽略，第三行字符数为40，比max大，set max=40……以此类推），用findstr "最大值" "文本"获得所有字符数最多的行

cobat

回复  慕夜蓝化
一般思路，逐行读取逐行统计字符数，并在每行标记上字符数（可用变量存储也可导出到临时文 ...
pcl_test 发表于 2015-3-9 12:29

    那贴的写法我没看懂,意思差不多对.

CrLf

回复 5# pcl_test


    不用 findstr 也行，设 max 的时候顺便设一个 maxline=%%a 就好

pcl_test

回复 7# CrLf
findstr是考虑max不止一行，而在运行过程中我们都不知道下一行是不是max的一行

CrLf

回复 8# pcl_test


    那可以这样：
maxline=!maxline!!换行!%%a

慕夜蓝化

如果排除查找相同数的最大行数,第二种应该说最快了。

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (a.txt) do (
   
4.     for /f "delims=:" %%a in ('(echo,%%i^&echo,^)^|findstr /o "."') do set/a len=%%a-3
   
5.     if not defined max set max=!len!
   
6.     if !len! geq !max! set max=!len!&set "#=%%i"
   
7.     )
   
8.     echo,%#%
   
9. pause
   

复制代码

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (堕落血天使.txt) do (
   
4.     set/a len=0&set "str=%%i$"
   
5.     for %%a in (4096,2048,1024,516,258,126,64,32,16,8,4,2,1) do (
   
6.         if not "!str:~%%a!"=="" set/a len+=%%a&set str=!str:~%%a!
   
7.     )
   
8.     if not defined max set max=!len!
   
9.     if !len! geq !max! set max=!len!&set "#=%%i"
   
10.     )
    
11. echo,%#%
    
12. pause
    

复制代码

apang

1. @echo off & setlocal enabledelayedexpansion
   
2. set Lf=^
   
3. 
   
4. 
   
5. for /f "delims=" %%a in (a.txt) do (
   
6.         set "s=%%a"
   
7.         set "Len=0"
   
8.         for %%b in (4096 2048 1024 512 256 128 64 32 16) do (
   
9.                 if "!s:~%%b!" NEQ "" set /a Len+=%%b & set "s=!s:~%%b!"
   
10.         )
    
11.         set "s=!s!fedcba9876543210"
    
12.         set /a Len+=0x!s:~16,1!
    
13.         if !Len! GEQ !Max! (
    
14.                 for %%b in (!Len!) do set "_%%b=!_%%b!%%a!Lf!"
    
15.                 set "Max=!Len!"
    
16.         )
    
17. )
    
18. echo,!_%Max%!
    
19. pause

复制代码

发现 set /a Len+=0x!s:~15,1! 是错误的，改一下，顺便改一下if判断逻辑

apang

好像也可以这样：

1. @set @n=0;// & cscript -nologo -e:jscript "%~0" < a.txt & pause & exit
   
2. 
   
3. s = WScript.StdIn.ReadAll() + "\r\n";
   
4. ar = s.split("\r\n").sort(function(x,y){return y.length-x.length});
   
5. for (i=0; i<ar.length-1; i++) {
   
6.         WScript.Echo(ar[i]);
   
7.         if (ar[i].length != ar[i+1].length) break;
   
8. }

复制代码

cobat

回复 11# apang


    又学到了,换行符好像可以直接赋值?

CrLf

回复 13# cobat


    变量表中除了分隔符 00 字符外，其他字符都可以保存到变量中

cobat

回复 14# CrLf


    学习了,频繁的用call有没有问题,延迟变量在标签里是什么情况.不懂的太多了.