【练习-019】批处理顺序排列文本内容

pusofalse · 发表于 2008-8-31 14:51:37

前些天在CN-DOS翻老帖，看到如此的一个题目，又加深了一点难度，有兴趣的来做下。
加分规则：
1.思路独特 5分
2.代码高效、通用 4分
3.技巧高超 4分
4.代码简洁 2分
5.完美代码 15分
题目如下：
a.txt内容：

A111
Assure
Cons tant
Smail
A012
Exa
Explosive
Weird
Admission
A077
Chant
Reli gious
Praise
Rhyming
Parsley
A034
Faith
Zealous
Absorb
Principle

复制代码

按照段落序号从小到大顺序排列，如下：

A012
Exa
Explosive
Weird
Admission
A034
Faith
Zealous
Absorb
Principle
A077
Chant
Reli gious
Praise
Rhyming
Parsley
A111
Assure
Cons tant
Smail

复制代码

每段的单词个数未知，在单词随机处有空格。
段落序号A之后的数字总是3位，若不够三位，则在前面加0表示。
A077，而不是A77。A034，而不是A34

[ 本帖最后由 pusofalse 于 2008-8-31 21:32 编辑 ]

youxi01 · 发表于 2008-8-31 19:13:20

从小到大排列

这句话应该说清楚：按各段落文字第一列数字大小顺序排列！
如：....

pusofalse · 发表于 2008-8-31 19:16:42

谢谢指正，已经修改！

terse · 发表于 2008-8-31 20:02:50

先发个粗糙的感觉可以精简

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n .* "1.txt"') do (
if "%%j"=="" (
for /f "tokens=1* delims=#" %%a in ("!str!") do (
set .%%a=%%a#%%b&set str=
))
if defined str (set str=!str!#%%j)else set str=%%j
)
for /f "tokens=1* delims=#" %%a in ("!str!") do set .%%a=%%a#%%b
for /f "tokens=2 delims==" %%i in ('set .') do (
set str=%%i
set "str=!str:#=&echo.!"
call:lp
)
pause&exit
:lp
echo %str%
echo.

复制代码

再改就这样没突破下面继续吧

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n .* "1.txt"') do (
if not "%%j"=="" (if defined str (set str=!str!#%%j)else set str=%%j)else set .!str!=ok&set str=
)
set .!str!=ok
for /f "tokens=1 delims=.=" %%i in ('set .') do (
set str=%%i
set "str=!str:#=&echo.!"
call:lp
)
pause&exit
:lp
echo %str%
echo.

复制代码

[ 本帖最后由 terse 于 2008-8-31 20:39 编辑 ]

pusofalse · 发表于 2008-8-31 20:14:46

刚看到这题时我感觉有点无从下手，但那只是被这题的外表所迷惑了而已。
感觉terse前辈考虑的有点过于复杂了。

terse · 发表于 2008-8-31 20:45:21

原帖由 pusofalse 于 2008-8-31 20:14 发表
刚看到这题时我感觉有点无从下手，但那只是被这题的外表所迷惑了而已。
感觉terse前辈考虑的有点过于复杂了。

试用sort 没成功
进了胡同

[ 本帖最后由 terse 于 2008-8-31 20:49 编辑 ]

pusofalse · 发表于 2008-8-31 20:57:59

我也用过sort，也没成功，可能还是思路不畅，同是用set来排的。
似乎都考虑到了这题只是合并第一个序号到第二个序号上一行的内容为一个变量，最后set自动排序。只是方法不同~

batman · 发表于 2008-8-31 22:12:29

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=:" %%i in ('findstr /n .* a.txt') do (
if not defined flag (
set "a=%%j"&set "flag=a"
) else (
if "%%j" neq "" (
call,set "_!a!=%%_!a!%% "%%j""
) else (
set "flag="
)
)
)
for /f "tokens=1,2 delims==" %%a in ('set _') do (
echo %%a
for %%i in (%%b) do echo %%~i
echo.
)
pause>nul

复制代码

batman · 发表于 2008-8-31 22:13:52

晕，贴出来才发现和terse的如同一辙。。。

huahua0919 · 发表于 2008-8-31 22:27:46

"只是合并第一个序号到第二个序号上一行的内容为一个变量"

不知道斑竹如何能够使一个回车能在set环境变量中存在?

pusofalse · 发表于 2008-8-31 22:56:14

兄所说的这种情况，恐怕是绝对不可能。或者误解我的意思了。
set var%n%=A012 Exa Explosive Weird Admission
for %%a in (!var%n%!) do echo %%a

huahua0919 · 发表于 2008-8-31 23:03:33

好象段中的字也空格的吧,这样写不会将字分开了吗

pusofalse · 发表于 2008-8-31 23:05:45

是分开了，加个"闭合就可以了啊。

pusofalse · 发表于 2008-9-1 21:23:26

这题果真难倒了新手吗，期待新手解答出此题。以下，本人的解，期待更加简洁的解。

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
set "var=%%a"
if "!var:~1,1!" leq "9" set "str=%%a"
call set ".!str!=%%.!str!%%"%%a" "
)
for /f "tokens=2 delims==" %%a in ('set .') do (
for %%i in (%%a) do echo %%~i
echo.
)
pause

复制代码

flyinspace · 发表于 2008-9-2 01:32:54

哦.看来只有另外想办法了....

利用skip吧..

@echo off
for /f "tokens=* " %%m in ('findstr /r "^A[0-9][0-9][0-9]$" 1.txt ^| sort /+1') do (
for /f "delims=: tokens=1,2 " %%i in ('findstr /n /r "^A[0-9][0-9][0-9]$" 1.txt') do if "%%j"=="%%m" echo %%m & call :loop %%i
echo.
)
goto :exit
:loop
for /f "skip=%1 tokens=* " %%n in (1.txt) do (
echo %%n| findstr /r "^A[0-9][0-9][0-9]$">nul
if not errorlevel 1 goto :EOF
echo %%n
)
goto :EOF
:exit
pause

复制代码

[ 本帖最后由 flyinspace 于 2008-9-3 14:59 编辑 ]

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

【练习-019】批处理顺序排列文本内容

回复 2楼的帖子

评分

回复 4楼的帖子

来凑下热闹

评分

回复 10楼的帖子

评分

评分

浏览过的版块

【练习-019】批处理顺序排列文本内容

回复 2楼 的帖子

评分

回复 4楼 的帖子

来凑下热闹

评分

回复 10楼 的帖子

评分

评分

浏览过的版块

回复 2楼的帖子

回复 4楼的帖子

回复 10楼的帖子