[已解决]文件名或路径%^怎么进行正常处理?

1139054012 · 发表于 2025-6-5 10:28:33

本帖最后由 1139054012 于 2025-6-5 13:40 编辑

功能是实现了,考虑到各种路径特殊符号【❤★!@#$%^&*()_+等
测试其他都解决了,就差%^不行,自动被识别bat内的指令

没方法了,看论坛大佬能否改成完美版,无论路径和文件夹再怎么用特殊字符,都能完美获取文件名,进行操作

@echo off
chcp 65001 >nul
:: 创建分类目录
mkdir "简体" 2>nul
mkdir "繁体" 2>nul
:: 初始化计数器
set /a success=0, fail=0
:: 第一轮处理：精确匹配_字幕01和_字幕02
for %%e in (ass srt ssa) do (
for /f "delims=" %%f in ('dir /b /a-d "*_字幕01*.%%e" 2^>nul') do (
call :safe_move "%%f" "简体" "_字幕01"
)
for /f "delims=" %%f in ('dir /b /a-d "*_字幕02*.%%e" 2^>nul') do (
call :safe_move "%%f" "繁体" "_字幕02"
)
)
:: 第二轮处理：识别.sc/.tc等后缀
for %%F in (*.ass *.srt *.ssa) do (
if exist "%%F" (
setlocal disabledelayedexpansion
set "filepath=%%F"
set "filename=%%~nF"
set "extension=%%~xF"
setlocal enabledelayedexpansion
set "subtype="
set "newname="
:: 检测简体后缀
if "!filename:~-3!"==".sc" (
set "subtype=sc"
set "newname=!filename:~0,-3!"
)
if not defined subtype if "!filename:~-4!"==".chs" (
set "subtype=sc"
set "newname=!filename:~0,-4!"
)
if not defined subtype if "!filename:~-5!"==".jpsc" (
set "subtype=sc"
set "newname=!filename:~0,-5!"
)
:: 检测繁体后缀
if not defined subtype if "!filename:~-3!"==".tc" (
set "subtype=tc"
set "newname=!filename:~0,-3!"
)
if not defined subtype if "!filename:~-4!"==".cht" (
set "subtype=tc"
set "newname=!filename:~0,-4!"
)
if not defined subtype if "!filename:~-5!"==".jptc" (
set "subtype=tc"
set "newname=!filename:~0,-5!"
)
:: 处理检测到的后缀类型
if defined subtype (
if "!subtype!"=="sc" set "targetdir=简体"
if "!subtype!"=="tc" set "targetdir=繁体"
set "newpath=!targetdir!\!newname!!extension!"
move "!filepath!" "!newpath!" >nul 2>&1
if exist "!newpath!" (
echo 已移动: !newname!!extension! → !targetdir!\
endlocal & endlocal & set /a success+=1
) else (
echo 移动失败: !filepath!
endlocal & endlocal & set /a fail+=1
)
) else (
endlocal & endlocal
)
)
)
:: 显示结果统计
echo.
echo 处理完成!
echo 成功: %success% 个文件
echo 失败: %fail% 个文件
echo 按任意键退出...
pause >nul
exit /b
:: 安全移动函数（处理特殊字符）
:safe_move
setlocal disabledelayedexpansion
set "file=%~1"
set "target=%~2"
set "pattern=%~3"
for %%A in ("%file%") do (
set "name=%%~nA"
set "ext=%%~xA"
)
setlocal enabledelayedexpansion
set "newname=!name:%pattern%=!"
set "newpath=!target!\!newname!!ext!"
move "!file!" "!newpath!" >nul 2>&1
if exist "!newpath!" (
echo 已移动: !newname!!ext! → !target!\
endlocal & endlocal & set /a success+=1
) else (
echo 移动失败: !file!
endlocal & endlocal & set /a fail+=1
)
exit /b

复制代码

移动失败: 1^^建_字幕01_chi.txt.ass
处理完成!
成功: 0 个文件
'�文件' is not recognized as an internal or external command,
operable program or batch file.
'��键退出...' is not recognized as an internal or external command,
operable program or batch file.

复制代码

文件名随便测试
新!$#%♥♡()【「〖❗：★☆🌟♥_+／_字幕02_chi.ass

77七 · 发表于 2025-6-5 11:37:35

set "_字幕01=简体"
set "_字幕02=繁体"
for %%e in (_字幕01 _字幕02) do (
for /f "delims=" %%f in ('dir /b /a-d "*%%e*.ass" "*%%e*.srt" "*%%e*.ssa" 2^>nul') do (
set nx=%%f
setlocal enabledelayedexpansion
md "!%%e!"
move "!nx!" "!%%e!\!nx:%%e=!"
endlocal
)
)

复制代码

有问题再说

aloha20200628 · 发表于 2025-6-5 13:28:03

本帖最后由 aloha20200628 于 2025-6-5 13:32 编辑

回复 1# 1139054012

楼主可先用以下代码覆盖一楼代码第8-115行后（须用utf-8编码存盘）运行，看是否能正确处理名为 "新!$#%♥♡(^)_+_字幕01_chi.ass" 的一类文件（我已调试通过）...

for %%w in ("_字幕01", "_字幕02") do for /f "delims=" %%f in (
'dir /b/a-d "*%%~w*.ass" "*%%~w*.srt" "*%%~w*.ssa" ') do (
set "w=%%~w" &set "name=%%~nf" &setlocal enabledelayedexpansion
set "newname=!name:%%~w=!"
if !w:~-1! equ 1 (set "newpath=简体\!newname!%%~xf") else (set "newpath=繁体\!newname!%%~xf")
move /y "!name!%%~xf" "!newpath!" &endlocal
)
exit/b

复制代码

1139054012 · 发表于 2025-6-5 13:39:48

本帖最后由 1139054012 于 2025-6-5 13:41 编辑

回复 3# aloha20200628

感谢回复,测试了下

'C:\!$#%♥♡' 不是内部或外部命令，也不是可运行的程序
或批处理文件。

C:\!$#%♥♡(^)_+_>

我这边不行,我还刻意用特殊文件夹和文件名测试,用楼上的改了下没问题了,就是直接替换计数会失效,需要额外处理下

aloha20200628 · 发表于 2025-6-5 14:33:23

本帖最后由 aloha20200628 于 2025-6-5 14:37 编辑

回复 4# 1139054012

用3楼代码又测试了当前目录下几个示例文件（接续一楼代码前6行），名如
"新!$#%♥♡(^)【「〖❗：★☆&#127&775;♥_+／_字幕01_chi.ass"
"新!$#%♥♡(^)【「〖❗：★☆&#127&775;♥_+／_字幕02_chi.srt"
"新【❤★!@#$%^&()_+_字幕01_chi.ass"
"新【❤★!@#$%^&()_+_字幕02_chi.srt"
均予顺利通过，代码改为 ansi（或 gb2312）编码存盘（删除一楼代码第2行）亦可顺利通过...

1139054012 · 发表于 2025-6-5 15:32:25

本帖最后由 1139054012 于 2025-6-5 16:15 编辑

回复 5# aloha20200628

忘加原来代码测试了

aloha20200628 · 发表于 2025-6-5 15:54:04

本帖最后由 aloha20200628 于 2025-6-5 15:59 编辑

回复 6# 1139054012

测试3楼代码须接续一楼代码前6行，若要直接运行3楼代码则须改用以下版本...

@echo off &md "简体" "繁体" 2>nul
for %%w in ("_字幕01", "_字幕02") do for /f "delims=" %%f in (
'dir /b/a-d "*%%~w*.ass" "*%%~w*.srt" "*%%~w*.ssa" ') do (
set "w=%%~w" &set "name=%%~nf" &setlocal enabledelayedexpansion
set "newname=!name:%%~w=!"
if !w:~-1! equ 1 (set "newpath=简体\!newname!%%~xf") else (set "newpath=繁体\!newname!%%~xf")
move /y "!name!%%~xf" "!newpath!" &endlocal
)
pause&exit/b

复制代码

其实在循环体内处理字符串 '怪异' 字符的要点，就是要在关闭变量延迟时先取值循环变量，如 set "name=%%~nF"，其后再开启变量延迟即可正确处理 !name! 变量中的'怪异'字符了。如果这类'怪异'字符可被系统默认的936码页覆盖，则不必切换当前系统默认码页，否则须切换当前码页，例如可包含更多'怪异'字符的65001码页...

1139054012 · 发表于 2025-6-5 16:08:27

本帖最后由 1139054012 于 2025-6-5 16:14 编辑

回复 7# aloha20200628

太感谢,犯傻了…一直处理文件,被这种特殊路径和文件名导致各种失效闪退问题, 这下可以完美解决疑难杂症了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]文件名或路径%^怎么进行正常处理?

评分

评分

评分