批处理如何ping指定IP延迟小于500ms 10次后启动指定程序？

差点就很帅 · 发表于 2024-10-17 10:09:06

ping 192.168.1.1
返回ping的延迟时间，如果小于500ms 10次则启动 D:\1.exe
如果超时或者其他异常也要返回具体内容。
如果是ping通的情况下显示为：
连接服务器测试  <1ms 第1次
连接服务器测试  <=1ms 第2次
依次类推
如果小于500ms 10次则启动D:\1.exe
如果是ping不通的情况下显示为：
连接服务器测试  超时第1次
连接服务器测试  超时第2次
如果是不通转为通了，要重新计数而且还要计算小于500ms 10次则启动 D:\1.exe
例如
连接服务器测试  超时第1次
连接服务器测试  超时第2次
连接服务器测试  >600ms 第1次
连接服务器测试  <700ms 第2次
连接服务器测试  <1ms 第1次
连接服务器测试  <=1ms 第2次
求大佬帮忙。

77七 · 发表于 2024-10-17 12:17:35

@echo off
rem 保存为ansi编码
setlocal enabledelayedexpansion
for /l %%l in () do (
set k=
for /f "delims==" %%a in ('2^>nul set _') do (
set %%a=
)
for /f "delims=" %%a in ('ping -n 1 192.168.1.1 2^>^&1 ^| findstr /rv "正在统计信息"') do (
set /a k+=101
set _!k:~-2!=%%a
)
(for /f "delims=" %%b in ('set _ ^| find /i "ttl="') do (
set str=%%b
for /f "delims=m=" %%c in ("!str:*时间=!") do (
if %%c lss 500 (
set /a n+=1,m=l=0
echo 连接服务器测试 %%c ms （^< 500ms）第!n!次
if !n! equ 10 (
start "" "d:\1.exe"
pause
exit
)
) else (
set /a m+=1,n=l=0
echo 连接服务器测试 %%b ms （^> 500ms）第!m!次
)
)
)) || (
set /a l+=1,m=n=0
echo 连接服务器测试超时第!l!次
for /f "tokens=1* delims==" %%a in ('set _') do (
echo errorinfo : [%%b]
)
)
timeout 1 >nul
echo=
)

复制代码

差点就很帅 · 发表于 2024-10-17 19:22:16

回复 2# 77七

感谢大佬的热心帮助！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理如何ping指定IP延迟小于500ms 10次后启动指定程序？

浏览过的版块