批处理从第一个文件读取每行内容，输出到第二个文件指定字符串后面怎么实现？求救

clayxin

第一个文本内容为用户名文本
a.txt（内容）
zhangsan
lisi
wanger
cuihua
读取a.txt的每行内容输出到另一个文本（b.txt）的文本中input的后面
b.txt(内容)
sdaadw
zxcz
input
sfwa

sdas
dasdas
geww
input
asdasdqqq

asda
rhhre
xoxhn
input
wegwg



我的大概思路是新建一个c.bat,读取a文件的每行并设为变量，再用finstr 找到b文件的input字符串 在后面加a生成的变量名。但今天才学bat不太会代码，求救！！！

Batcher

回复 1# clayxin


请参考Q-04和Q-05把bat文件和txt文件都保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

1. @echo off
   
2. cd /d "%~dp0"
   
3. set "KeyStr=input"
   
4. (for /f "tokens=1* delims=:" %%a in ('findstr /n .* "b.txt"') do (
   
5.     set "ThisStr=%%b"
   
6.     setlocal enabledelayedexpansion
   
7.     echo,!ThisStr!
   
8.     if "!ThisStr!" equ "%KeyStr%" (
   
9.         type "a.txt"
   
10.     )
    
11.     endlocal
    
12. ))>"c.txt"

复制代码

qixiaobin0715

我想楼主的需求应当是这样的：

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (a.txt) do (
   
4.     set /a n+=1
   
5.     set _!n!=%%i
   
6. )
   
7. (for /f "tokens=1* delims=:" %%i in ('findstr /n .* b.txt') do (
   
8.     echo,%%j
   
9.     if "%%j"=="input" (
   
10.         set /a m+=1
    
11.         for %%k in (_!m!) do echo,!%%k!
    
12.     )
    
13. ))>c.txt
    
14. pause

复制代码

Nsqs

1. powershell -noprofile -executionpolicy bypass "(gc b.txt) -replace '(?<=^input)',"`r`n$(gc a.txt -raw)"" >c.txt

复制代码

读a.txt与b.txt 最后输出 c.txt

clayxin

谢谢大佬们，已经解决了。！！