批处理如何将前几位相同数字的文件，转移到相同文件名的文件夹中？

脑袋大

各位大佬好，想请教一下，有没有什么办法可以将红框内的前几位相同数字的文件，转移到右侧建好的相同文件名的文件夹中吗？

Batcher

回复 1# 脑袋大


请给一个真实的例子说明一下你的需求吧。
如果需要上传文件，可以用阿里云盘或百度网盘。

如果需要上传截图，可以找个图床，例如：
http://bbs.bathome.net/thread-60985-1-1.html

Batcher

回复 1# 脑袋大


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA
test.bat和你的pdf文件放在同一个文件夹下执行

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
   
4.     set "FileName=%%i"
   
5.     setlocal enabledelayedexpansion
   
6.     set "FolderName=!FileName:~0,19!"
   
7.     if not exist "!FolderName!" (
   
8.         md "!FolderName!"
   
9.     )
   
10.     move "%%i" "!FolderName!"
    
11.     endlocal
    
12. )

复制代码

脑袋大

回复 3# Batcher


    再麻烦一下大佬，执行之后建好的文件夹下，能不能再建三个子文件夹：1.原地籍档案 2.变化原因 3.国有    ；然后文件夹下的PDF文件放进文件夹1.原地籍档案中，批处理能做到吗？[img][/img]

Batcher

回复 4# 脑袋大

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
   
4.     set "FileName=%%i"
   
5.     setlocal enabledelayedexpansion
   
6.     set "FolderName=!FileName:~0,19!"
   
7.     if not exist "!FolderName!" (
   
8.         md "!FolderName!\1.原地籍档案"
   
9.         md "!FolderName!\2.变化原因"
   
10.         md "!FolderName!\3.国有"
    
11.     )
    
12.     move "%%i" "!FolderName!\1.原地籍档案"
    
13.     endlocal
    
14. )

复制代码

qixiaobin0715

如果你顶楼所说的文件夹预先已创建，这样也行：

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /ad') do (
   
3.     if exist %%i*.pdf (
   
4.         md "%%i\1.原地籍档案"
   
5.         md "%%i\2.变化原因"
   
6.         md "%%i\3.国有"
   
7.         move "%%i*.pdf" "%%i\1.原地籍档案"
   
8.     )
   
9. )

复制代码

qixiaobin0715

如果是执行3楼代码后，要继续完成4楼任务：

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /ad') do (
   
3.     md "%%i\1.原地籍档案"
   
4.     md "%%i\2.变化原因"
   
5.     md "%%i\3.国有"
   
6.     move "%%i\*.pdf" "%%i\1.原地籍档案"
   
7. )

复制代码

开始代码有误，已修改