【已解决】批处理如何剪切第一、第二和最后一个文件？

F090706 · 发表于 2022-4-26 19:59:51

本帖最后由 F090706 于 2022-4-27 21:25 编辑

有多个文件夹，000001、000002、000003，大约1000个左右
想把每个文件夹中的第一、第二和最后一个文件重命名，加上所在文件夹的名称，中间用“-”隔开，然后剪切出来，都是tif图片格式的图片，文件命名都是001、002、003
有没有bat的脚本，多谢大神们了

Batcher · 发表于 2022-4-26 22:10:00

回复 1# F090706

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
REM 设置图片移动到哪个文件夹
set "DstFolder=结果"
cd /d "%~dp0"
setlocal enabledelayedexpansion
if not exist "%DstFolder%\" (
md "%DstFolder%"
)
for /f "delims=" %%i in ('dir /b /ad ^| findstr /v /x "%DstFolder%"') do (
echo 正在处理文件夹：%%i
pushd "%%i"
set n=0
for /f "delims=" %%j in ('dir /b /a-d *.tif') do (
set /a n+=1
if !n! equ 1 (
move "%%j" "..\%DstFolder%\%%i-%%j"
) else if !n! equ 2 (
move "%%j" "..\%DstFolder%\%%i-%%j"
) else (
set "LastFile=%%j"
)
)
move "!LastFile!" "..\%DstFolder%\%%i-!LastFile!"
popd
)

复制代码

F090706 · 发表于 2022-4-27 21:24:30

回复 2# Batcher

多谢大神，忙了一天这个事，真的太感谢了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】批处理如何剪切第一、第二和最后一个文件？