有个批处理imagemagick的需求，不知道有会做的朋友吗？

schubert

有偿服务，

需要一批图片批量加相框，然后缩放到背景图，背景图使用图片的主色调。

Batcher

回复 1# schubert


你说的加相框是这个效果吗：

1. @echo off
   
2. set "SrcFolder=C:\Users\Administrator\Desktop\1"
   
3. set "DstFolder=C:\Users\Administrator\Desktop\2"
   
4. set "convert=convert.exe"
   
5. if not exist "%DstFolder%" (
   
6.     md "%DstFolder%"
   
7. )
   
8. if not exist "%SrcFolder%" (
   
9.     echo 找不到待处理的图片文件夹
   
10.     pause
    
11.     goto :eof
    
12. )
    
13. for /f "delims=" %%i in ('dir /b /a-d "%SrcFolder%\*.jpg"') do (
    
14.     echo 正在处理图片：%%i
    
15.     "%convert%" "%SrcFolder%\%%i" -bordercolor "#ddddff" -border 25x25 "%DstFolder%\%%i"
    
16. )
    
17. pause

复制代码

schubert

回复 2# Batcher

是已经加相框，但需要有带相框阴影，另外生成背景的那种。

schubert

回复 2# Batcher


或者直接加相框阴影，背景设置透明，另外用png格式保存，不知道convert.exe是否能实现背景透明的png文件保存

Batcher

回复 4# schubert


1楼的需求描述里面没有提到阴影效果，你试试这样：

1. @echo off
   
2. set "SrcFolder=C:\Users\Administrator\Desktop\1"
   
3. set "DstFolder=C:\Users\Administrator\Desktop\2"
   
4. set "montage=montage.exe"
   
5. if not exist "%DstFolder%" (
   
6.     md "%DstFolder%"
   
7. )
   
8. if not exist "%SrcFolder%" (
   
9.     echo 找不到待处理的图片文件夹
   
10.     pause
    
11.     goto :eof
    
12. )
    
13. for /f "delims=" %%i in ('dir /b /a-d "%SrcFolder%\*.jpg"') do (
    
14.     echo 正在处理图片：%%i
    
15.     "%montage%" "%SrcFolder%\%%i" -shadow -geometry +20+20 -background none -resize x500 -bordercolor black -border 15x15 "%DstFolder%\%%~ni.png"
    
16. )
    
17. pause

复制代码

schubert

回复 5# Batcher


   
不知道是否可以处理文件夹下面的所有子文件夹和文件，并保存在指定的新的文件夹中，按照原文件夹结构

另外产生了一个错误，不过好像又不妨碍新图片的产生。

就是下面这个

正在处理图片：0009.jpg
montage.exe: UnableToOpenConfigureFile `magic.xml' @ warning/configure.c/GetConfigureOptions/714.
montage.exe: UnableToOpenConfigureFile `colors.xml' @ warning/configure.c/GetConfigureOptions/714.
montage.exe: UnableToOpenConfigureFile `type.xml' @ warning/configure.c/GetConfigureOptions/714.
正在处理图片：0010.jpg
montage.exe: UnableToOpenConfigureFile `magic.xml' @ warning/configure.c/GetConfigureOptions/714.
montage.exe: UnableToOpenConfigureFile `colors.xml' @ warning/configure.c/GetConfigureOptions/714.
montage.exe: UnableToOpenConfigureFile `type.xml' @ warning/configure.c/GetConfigureOptions/714.

Batcher

回复 6# schubert


    imagemagick安装好了之后会有好几个xml文件你把它们跟montage.exe放在一起就不会有这些报错了

schubert

回复 7# Batcher


    可以让他处理文件夹下的所有文件和子文件夹么？

Batcher

回复 8# schubert

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. REM 处理该文件夹下（包括子文件夹）的图片
   
4. set "SrcFolder=C:\Users\Administrator\Desktop\1"
   
5. REM 指定处理之后的图片放到哪个文件夹
   
6. set "DstFolder=C:\Users\Administrator\Desktop\2"
   
7. set "montage=montage.exe"
   
8. if not exist "%DstFolder%" (
   
9.     md "%DstFolder%"
   
10. )
    
11. if not exist "%SrcFolder%" (
    
12.     echo 找不到待处理的图片文件夹
    
13.     pause
    
14.     goto :eof
    
15. )
    
16. for /f "delims=" %%i in ('dir /b /s /a-d "%SrcFolder%\*.jpg"') do (
    
17.     echo 正在处理图片：%%i
    
18.     set "SrcFull=%%i"
    
19.     set "DstSub=%DstFolder%!SrcFull:%SrcFolder%=!"
    
20.     for %%j in ("!DstSub!") do (
    
21.         if not exist "%%~dpj" (
    
22.             md "%%~dpj"
    
23.         )
    
24.         "%montage%" "%%i" -shadow -geometry +20+20 -background none -resize x500 -bordercolor black -border 15x15 "%%~dpj%%~ni.png"
    
25.     )
    
26. )
    
27. pause

复制代码

schubert

回复 9# Batcher


    非常感谢，已经可以使用了，

我再研究研究怎么让阴影明显点，感觉投影阴影稍微浅了点

Batcher

回复 1# schubert


背景图使用图片的主色调

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. REM 处理该文件夹下（包括子文件夹）的图片
   
4. set "SrcFolder=C:\Users\Administrator\Desktop\1"
   
5. REM 指定处理之后的图片放到哪个文件夹
   
6. set "DstFolder=C:\Users\Administrator\Desktop\2"
   
7. REM 根据自己电脑实际情况设置ImageMagick的路径
   
8. set "path=C:\Program Files\ImageMagick;%path%"
   
9. 
   
10. if not exist "%DstFolder%" (
    
11.     md "%DstFolder%"
    
12. )
    
13. if not exist "%SrcFolder%" (
    
14.     echo 找不到待处理的图片文件夹
    
15.     pause
    
16.     goto :eof
    
17. )
    
18. for /f "delims=" %%i in ('dir /b /s /a-d "%SrcFolder%\*.jpg"') do (
    
19.     echo 正在处理图片：%%i
    
20.     set "MeanRGB="
    
21.     for /f "tokens=2" %%a in ('identify.exe -verbose "%%i" ^| find "mean:"') do (
    
22.         set "MeanRGB=!MeanRGB! %%a"
    
23.     )
    
24.     for /f "tokens=1-3" %%a in ("!MeanRGB!") do (
    
25.         set "MeanRGB=%%a,%%b,%%c"
    
26.     )
    
27.     echo rgb^(!MeanRGB!^)
    
28.     set "SrcFull=%%i"
    
29.     set "DstSub=%DstFolder%!SrcFull:%SrcFolder%=!"
    
30.     for %%j in ("!DstSub!") do (
    
31.         if not exist "%%~dpj" (
    
32.             md "%%~dpj"
    
33.         )
    
34.         montage.exe "%%i" -shadow -geometry +20+20 -background rgb^(!MeanRGB!^) -resize x500 -bordercolor black -border 15x15 "%%~dpj%%~ni.png"
    
35.     )
    
36. )
    
37. pause

复制代码

schubert

回复 11# Batcher


   

给力！！！

schubert

回复 11# Batcher

可以让最后的效果图长宽比1:1么

schubert

回复 11# Batcher

还有个想改进下的，就是想把图片统一放到同一个背景下应该怎么定义呢？