[已解决]关于 批处理删除文件夹的 bug ？

慕夜蓝化

1. 
   
2. @echo off
   
3. ECHO 清理target中的所有内容
   
4. 
   
5. 
   
6. set "projectDir=H:\InReason\irapy_x64"
   
7. for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
   
8.     echo %%i|findstr "target$" >nul&&echo,指定要删除的文件夹---：%%i&rd /s /q %%i
   
9. )
   

复制代码

结果 我想要的删除的没删掉。
而是 所有的 不包含指定条件的被删除了。
好在我这边做了备份，不然所有的文件都没了。

然后，我做了一个更改。

1. 
   
2. for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
   
3.     echo %%i|findstr "target$" >nul&&rd /s /q %%i
   
4. )
   

复制代码

我把那个 echo 拿掉 就正常了。

xczxczxcz

不是BUG，是第7行的&rd xxxx和前面的findstr结果没有任何瓜果关系。而是一个独立的命令行。

Batcher

回复 1# 慕夜蓝化


用if命令可以避免出现【&、&&代码实际语法跟你的想象不一样】的问题：

1. @echo off
   
2. set "projectDir=H:\InReason\irapy_x64"
   
3. for /f "delims=" %%i in ('dir /s /b /l /ad "%projectDir%"') do (
   
4.     echo %%i|findstr "target$" >nul
   
5.     if errorlevel 1 (
   
6.         echo 不符合删除条件的文件夹---：%%i
   
7.     ) else (
   
8.         echo 指定要删除的文件夹---：%%i
   
9.         rd /s /q "%%i"
   
10.     )
    
11. )

复制代码

还可以试试把findstr命令放到for循环的fileset里面，避免循环内部重复调用findstr命令导致代码效率较低：

1. @echo off
   
2. set "projectDir=H:\InReason\irapy_x64"
   
3. for /f "delims=" %%i in ('dir /s /b /l /ad "%projectDir%"^|findstr "target$"') do (
   
4.     echo 指定要删除的文件夹---：%%i
   
5.     rd /s /q "%%i"
   
6. )

复制代码

慕夜蓝化

回复 2# xczxczxcz


    可是，如果只有

1. && echo,%%i

复制代码

所显示出的结果确实是正确的，而且使用

1. &&echo,%%i&del /s /q %%i

复制代码

也是完全没有问题的。
问题就出现在 换了 rd 命令 立马出错，变成了不包含条件的全部删除了。

慕夜蓝化

回复 3# Batcher


    谢谢batcher大大，我这边已经解决了。
   解决办法，是添加一个括号，将如果正确情况下要执行的语句全部括起来就可以了。

1. 
   
2. set "projectDir=H:\InReason\irapy_x64"
   
3. for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
   
4.     echo %%i|findstr "target$" >nul&&(echo,指定要删除的文件夹---：%%i&rd /s /q %%i)
   
5. )
   

复制代码