[已解决]如何批量去除或替换文件夹名称及子文件夹名称中的重复字符

thp2008 · 发表于 2020-4-18 23:50:55

本帖最后由 thp2008 于 2020-4-20 17:59 编辑

[NASI.si-银河系] ABS 2015.02.25 No.1100
[NASI.si-银河系] ABS 2015.02.27 No.1101
[NASI.si-银河系] ABS 2015.03.02 No.1102
[NASI.si-银河系] ABS 2015.03.04 No.1103
[NASI.si-银河系] ABS 2015.03.06 No.1104
[NASI.si-银河系] ABS 2015.03.11 No.1106
[NASI.si-银河系] ABS 2015.03.13 No.1107
[NASI.si-银河系] ABS 2015.03.16 No.1108

打个比方，像上面这种文件夹名称，如果用批处理批量去除或替换掉，[NASI.si-银河系] ABS 这种字符串，包括子文件夹名称，一起去除或替换，请高手帮助，谢谢！

went · 发表于 2020-4-19 12:32:10

本帖最后由 went 于 2020-4-19 12:54 编辑

ANSI编码

@echo off
REM 主文件夹
set "folder=C:\Users\lenovo\Desktop\[NASI.si-银河系] ABS 2015.02.25 No.1100"
REM 要替换的字符串
set "key1=[NASI.si-银河系] ABS "
REM 替换成的字符串
set "key2="
:loop
REM 重命名子文件夹
for /f "delims=" %%i in ('dir /s /b /ad "%folder%\*%key1%*" ^| sort /r') do call :renameFolder "%%~i"
REM 检查,长路径错误
dir /s /b /ad "%folder%\*%key1%*" >nul 2>nul && echo again... && goto :loop
REM 重命名主文件夹
for /f "delims=" %%i in ("%folder%") do call :renameFolder "%%~i"
pause&exit
:renameFolder
set "dir=%~nx1"
call set "dir=%%dir:%key1%=%key2%%%"
echo %~1
echo %dir%
rename "%~1" "%dir%" && echo 成功! || echo 失败!
echo ----------------------------------------------------
goto :eof

复制代码

thp2008 · 发表于 2020-4-20 17:53:49

你好，很感谢您的帮助，经过仔细的测试，发现是可以的正常运行及更名的，我在你写的基础细化了一下，人工输入。测试也没有问题。
但我后来发现，这个有个小BUG，就是如果我如果替换后字符串，包含Key1的字符串的话，批处理就会无限循环，一直改一下去。
可不可以，只让批处理，只对所有文件夹只运行一遍，不再重复运行了，就可以消除这个BUG，但是如果不行的话，也没事，我已经知道这个BUG了。
其它都是可以正常改名的，包括文件夹名称中有空格，中文及字符都是可以正常运行的。看得出，您对批处理很有研究，再次感谢您的帮助。

@echo off
ECHO.
ECHO 批量文件夹改名批处理
ECHO.
ECHO 说明：本批处理，可以对指定的文件夹及其所有子文件夹名称中，重复的字符串批量进行替换或删除。
ECHO.
REM 主文件夹
REM 如果手工输入需要更名的文件夹目录，去掉REM
REM set /p folder=请输入需要改文件夹名的路径：
REM 本批处理需要拷贝到需要更名的主目录，自动获取需要更名目录的路径,如需手工输入，请REM掉下面这行。
set folder=%~dp0
REM 要替换的字符串
ECHO.
ECHO.
set /p key1=请输入需要替换的文件夹名称中的重复字符串:
REM 替换成的字符串
ECHO.
ECHO.
echo 提示:如果不输入任何替换后的字符，直接回车，就是删除掉文件夹名称中上述提供的重复部分
set /p key2=请输入替换后的字符串：
:loop
REM 重命名子文件夹
for /f "delims=" %%i in ('dir /s /b /ad "%folder%\*%key1%*" ^| sort /r') do call :renameFolder "%%~i"
REM 检查,长路径错误
dir /s /b /ad "%folder%\*%key1%*" >nul 2>nul && echo again... && goto :loop
REM 重命名主文件夹
for /f "delims=" %%i in ("%folder%") do call :renameFolder "%%~i"
pause&exit
:renameFolder
set "dir=%~nx1"
call set "dir=%%dir:%key1%=%key2%%%"
echo %~1
echo %dir%
rename "%~1" "%dir%" && echo 成功! || echo 失败!
echo ----------------------------------------------------
goto :eof

复制代码

went · 发表于 2020-4-20 19:56:36

回复 3# thp2008
把这行注释掉

REM dir /s /b /ad "%folder%\*%key1%*" >nul 2>nul && echo again... && goto :loop

复制代码

thp2008 · 发表于 2020-4-20 20:09:43

回复 4# went

好的，可以了。谢谢

发霉的萝卜 · 发表于 2023-5-12 13:48:25

回复 4# went

提示拒绝访问，失败该怎么解决呀

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]如何批量去除或替换文件夹名称及子文件夹名称中的重复字符

评分

评分