[已解决]批处理如何给lnk快捷方式文件添加快捷键/热键和更改显示图标？

ygqiang

[已解决]bat批处理，如何给lnk文件添加快捷键？比如CTRL+SHIFT+L

pcl_test

回复 1# ygqiang

1. set "back_d=C:\WINDOWS\system32"
   
2. set "back_dir=C:\WINDOWS\system32\logoff.exe"
   
3. ::指定图标路径
   
4. set "back_ico=%windir%\system32\shell32.dll,44"
   
5. del /q "%userprofile%\「开始」菜单\注销.lnk"
   
6. 
   
7. ::创建文件的快捷方式（普通位置）
   
8. (echo Set objShell=CreateObject^("WScript.Shell"^)
   
9. echo Set objlink=objShell.CreateShortcut^("%userprofile%\「开始」菜单\注销.lnk"^)
   
10. echo objlink.Hotkey="CTRL+L"
    
11. echo objlink.WindowStyle=3
    
12. echo objlink.TargetPath="%back_dir%"
    
13. echo objlink.WorkingDirectory="%back_d%"
    
14. ::设置图标
    
15. echo objlink.IconLocation="%back_ico%"
    
16. echo objlink.Save
    
17. )>"mysendto.vbs"
    
18. start /wait "" "mysendto.vbs"
    
19. del "mysendto.vbs"

复制代码

pcl_test

回复 1# ygqiang

1. @echo off
   
2. rem 创建exe文件的lnk快捷方式
   
3. ::指定路径和名称
   
4. set "LnkFile=%userprofile%\「开始」菜单\注销.lnk"
   
5. ::指定主程序
   
6. set "TargetPath=%SystemRoot%\system32\logoff.exe"
   
7. ::指定起始位置
   
8. set "WorkingDirectory=%SystemRoot%\system32"
   
9. ::指定快捷键
   
10. set "Hotkey=Ctrl+Shift+L"
    
11. ::指定图标
    
12. set "IconLocation=%windir%\system32\shell32.dll,44"
    
13. del "%LnkFile%" /f /q >nul 2>nul
    
14. call :CreateShort "%LnkFile%" "%TargetPath%" "%WorkingDirectory%" "%HotKey%" "%IconLocation%"
    
15. pause & exit
    
16. 
    
17. ::Arguments              目标程序参数
    
18. ::Description            快捷方式备注
    
19. ::FullName               返回快捷方式完整路径
    
20. ::Hotkey                 快捷方式快捷键
    
21. ::IconLocation           快捷方式图标，不设则使用默认图标
    
22. ::TargetPath             目标
    
23. ::WindowStyle            窗口启动状态
    
24. ::WorkingDirectory       起始位置
    
25. 
    
26. :CreateShort
    
27. mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(""%~1""):b.TargetPath=""%~2"":b.WorkingDirectory=""%~3"":b.HotKey=""%~4"":b.IconLocation=""%~5"":b.Save:close")
    
28. goto :eof

复制代码

pcl_test

回复 1# ygqiang

1. ' 2>nul& @echo off & cls
   
2. ' 2>nul& del "%userprofile%\「开始」菜单\注销.lnk" /f /q >nul 2>nul
   
3. ' 2>nul& cscript -nologo -e:vbscript %~fs0
   
4. ' 2>nul& pause & exit /b
   
5. Set a=CreateObject("WScript.Shell")
   
6. userprofile=a.expandenvironmentstrings("%userprofile%")
   
7. windir=a.expandenvironmentstrings("%windir%")
   
8. Set b=a.CreateShortcut(userprofile & "\「开始」菜单\注销.lnk")
   
9. b.TargetPath=windir & "\system32\logoff.exe"
   
10. b.WorkingDirectory=windir & "\system32"
    
11. b.HotKey="Ctrl+Shift+L"
    
12. b.IconLocation=windir & "\system32\shell32.dll,44"
    
13. b.Save

复制代码

pcl_test

回复 1# ygqiang

1. if ($true){}# == ($true){}# goto _batch
   
2. <#BeginBat#
   
3. :_batch
   
4. @echo off&setlocal&cls
   
5. del "%userprofile%\「开始」菜单\注销.lnk" /f /q >nul 2>nul
   
6. (echo $strPath="%~dp0"&type "%~f0")|powershell -command -
   
7. pause
   
8. exit/b 0
   
9. #EndBat#>
   
10. 
    
11. $shell = New-Object -ComObject WScript.Shell
    
12. $lnkpath = [System.Environment]::GetFolderPath(7)
    
13. $windir = [System.Environment]::GetFolderPath(37)
    
14. $lnkfile = $shell.CreateShortcut("$lnkpath\注销.lnk")
    
15. $lnkfile.TargetPath="$windir\logoff.exe"
    
16. $lnkfile.WorkingDirectory="$windir"
    
17. $lnkfile.HotKey="Ctrl+Shift+L"
    
18. $lnkfile.IconLocation="$windir\shell32.dll,44"
    
19. $lnkfile.Save()

复制代码