求助解决VBS获取网络上的时间校准本机系统时间的代码报错的原因

hnldwhm52

老师下了以下VBS校准系统时间在有线网络行，无线就不行，请修改！！谢谢！！
http://www.bathome.net/redirect. ... 4203&ptid=21616
运行vbs显示提示如下：

hnldwhm52

回复 2# yu2n
yu2n老师您好！！
        我是新手，是来学习的！！

yu2n

回复 2# hnldwhm52

这个『有线网络行，无线就不行』问题太广，但是跟VBS有关系么？
你要真觉得是无线网络问题，去把无线网络搞好不就行了。
你要真是来问问题的，把系统、运行环境、怎么操作出错的，给写明白了。

apang

我来改一下，不是因为lz所说的“无线网络不能用”，而是为了win7开启uac时双击能用，另外时区更改了不受影响

1. call runAsAdmin()
   
2. strNewDateTime = convertDateTime(getBaiduTime())
   
3. call syncDateTime(strNewDateTime, Now())
   
4. 
   
5. Function getBaiduTime()
   
6.     Dim strUrl, strText
   
7.     strUrl = "http://open.baidu.com/special/time/"
   
8.     With CreateObject("MSXML2.XmlHttp")
   
9.         .Open "GET", strUrl, False
   
10.         .Send()
    
11.         strText = .responseText
    
12.     End With
    
13.     strText = Split(LCase(strText), "window.baidu_time(")(1)
    
14.     getBaiduTime = Int(Left(strText, 13)/1000)
    
15. End Function
    
16. 
    
17. Function convertDateTime(intUnixTime)
    
18.     Dim objWMI, colOSes, objOS, tmZone
    
19.     Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
    
20.     Set colOSes =objWMI.ExecQuery("Select * from Win32_OperatingSystem")
    
21.     For Each objOS in colOSes
    
22.         tmZone = objOS.CurrentTimeZone
    
23.     Next
    
24.     intUnixTime = intUnixTime + tmZone * 60
    
25.     convertDateTime = DateAdd("s", intUnixTime, "1970-1-1 00:00:00")
    
26. End Function
    
27. 
    
28. Sub syncDateTime(ByVal strNewDateTime, strOldDateTime)
    
29.     Dim ss, objDateTime, dtmNewDateTime
    
30.     ss = DateDiff("s", strOldDateTime, strNewDateTime)
    
31.     If Abs(ss) < 1 Then
    
32.         MsgBox "本机时间非常准确无需校对！"
    
33.         Exit Sub
    
34.     End If
    
35. 
    
36.     Set objDateTime = CreateObject("WbemScripting.SWbemDateTime")
    
37.     objDateTime.SetVarDate strNewDateTime, true
    
38.     dtmNewDateTime = objDateTime.Value
    
39. 
    
40.     Dim objWMI, colOSes, objOS
    
41.     Set objWMI = GetObject("winmgmts:{(Systemtime)}\\.\root\cimv2")
    
42.     Set colOSes =objWMI.ExecQuery("Select * from Win32_OperatingSystem")
    
43.     For Each objOS in colOSes
    
44.         objOS.SetDateTime dtmNewDateTime
    
45.     Next
    
46.     MsgBox "校准前：" & strOldDateTime & vbLf & "校准后：" & Now()
    
47. End Sub
    
48. 
    
49. Sub runAsAdmin()
    
50.     Dim objWMI, colOSes, objOS, strVer
    
51.     Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
    
52.     Set colOSes =objWMI.ExecQuery("Select * from Win32_OperatingSystem")
    
53.     For Each objOS in colOSes
    
54.         strVer = Split(objOS.Version, ".")(0)
    
55.     Next
    
56.     If CInt(strVer) >= 6 Then
    
57.         Dim objShell
    
58.         Set objShell = CreateObject("Shell.Application")
    
59.         If WScript.Arguments.Count = 0 Then
    
60.             objShell.ShellExecute "WScript.exe", _
    
61.                 """" & WScript.ScriptFullName & """ OK", , "runAs", 1
    
62.             Set objShell = Nothing
    
63.             WScript.Quit
    
64.         End If
    
65.     End If
    
66. End Sub
    

复制代码

ygqiang

我来改一下，不是因为lz所说的“无线网络不能用”，而是为了win7开启uac时双击能用，另外时区更改了不受影响 ...
apang 发表于 2015-1-20 21:26

    而是为了win7开启uac时双击能用？？？

这个是啥意思？你的vbs代码，与1楼的相比，有啥差别呢？


明白了。多谢。。。
有人说：“win7下，不是所有vbs都可以运行  包括其它一些程序  有些需要权限
call runAsAdmin()    这个就是获取win7下管理员权限的命令

下面有个runAsAdmin()   自定义函数，作用就是获取权限”

hnldwhm52

我来改一下，不是因为lz所说的“无线网络不能用”，而是为了win7开启uac时双击能用，另外时区更改了不受影响 ...
apang 发表于 2015-1-20 21:26

i
谢谢apang老师旳热心指教解答！

yiwuyun

没看懂那个OK是什么意思，如果没有，就会出问题，但如果改成任何其他字符串，都不会出问题。
objShell.ShellExecute "WScript.exe", """" & WScript.ScriptFullName & """ OK", , "runAs", 1
按一些资料的解释，第二个参数应该是WScript.exe的参数，但它需要这个ＯＫ参数吗？

apang

回复 7# yiwuyun


    如你所说，OK就是一参数名字，可以用其它字符替代，但它是WScript.exe的参数，WScript.Arguments.Count 就是WScript.exe的参数个数
如果把它当作objShell.ShellExecute 的参数，那它是多余的

yiwuyun

谢谢，想了一晚上，懂了，ok不是要传给ws的，而是要传给vbs的。代码很清晰，写得很好。比楼主的那个代码清晰多了。