[已解决]批处理怎样给zip文件的文件名结尾加个4位随机字符串？

WisdomFusion · 发表于 2014-7-19 10:48:43

本帖最后由 WisdomFusion 于 2014-7-19 15:16 编辑

如当前文件夹里有

111.zip
222.zip
333.zip
...

想批量move成

111_h7ye.zip
222_ui89.zip
333_7hy9.zip
...

下面是我测试用的代码，一直调不通，请高手帮忙看看，谢谢

@ECHO OFF & SETLOCAL EnableDelayedExpansion
FOR %%f IN (DIR /B *.zip) DO (
SET file=%%f
SET "file=!file:.zip=!"
set pas=
set s=abcdefghijklmnopqrstuvwxyz1234567890
set m=0
:loop
set /a n=%random% %% 36
call set pas=%pas%%%s:~%n%,1%%
set /a m=m+1
if not %m%==4 goto loop
MOVE "%%f" "!file!_%pas%.zip"
)

复制代码

apang · 发表于 2014-7-19 11:47:34

@ECHO OFF & SETLOCAL EnableDelayedExpansion
set "s=abcdefghijklmnopqrstuvwxyz1234567890"
FOR /f "delims=" %%f IN ('DIR /B *.zip') DO (
set "pas="
for /l %%a in (1 1 4) do (
set /a n=!random! %% 36
for %%b in (!n!) do set "pas=!pas!!s:~%%b,1!"
)
MOVE "%%f" "%%~nf_!pas!.zip"
)
pause

复制代码

WisdomFusion · 发表于 2014-7-19 12:12:35

回复 2# apang

谢谢，成功了，而且代码更简法了，多谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理怎样给zip文件的文件名结尾加个4位随机字符串？