批处理实现分区对齐查询,4K对齐查询

foxJL

更新一下,添加对U盘和移动硬盘的查询

1. 
   
2. @echo off&setlocal EnableDelayedExpansion
   
3. color 3f & title 分区对齐查询  by foxjl   bathome.net做最实用的批处理论坛
   
4. ::做这个分区对齐查询,主要是为了方便大家查看电脑分区有没有4K对齐,4K对齐虽说不是什么新技术,但还是有大部分电脑没有对齐的,特别在固态硬盘日益普及的今天,4K对齐就非常有必要了。
   
5. ::另外机械硬盘也要4K对齐,有人测试过,复制文件时,对齐4K后性能有着明显的提高,特别是在零散小文件方面,有着接近一倍的提升,这也间接证明了对齐4K后,可以有效缓解系统卡顿情况发生。
   
6. ::在编写过程中绕了不少弯路,感谢batman、fastslz、Broly的帮助.
   
7. ::2013.9.20添加对U盘和移动硬盘的查询.
   
8. >%temp%\tmp.vbs echo Wscript.Echo round(wscript.arguments(0)/wscript.arguments(1),2)
   
9. for /f "skip=1" %%i in ('wmic path Win32_LogicalDiskToPartition get StartingAddress') do (set /a n+=1 & set StartingAddress_!n!=%%i)
   
10. for %%i in (3,2) do (
    
11.   for /f "tokens=1,2,3 delims= " %%a in ('wmic logicaldisk where "drivetype=%%i" get deviceid^,size^,freespace 2^>nul^|find ":"') do (
    
12.     if %%i equ 3 (echo.Disk %%a) else (echo.Usb Disk %%a)
    
13.     set /a n_2+=1
    
14.     call :calculate %%b 1073741824 availableGB
    
15.     call :calculate %%c 1073741824 allGB
    
16.     for %%z in (!n_2!) do (set StartingAddress=!StartingAddress_%%z!)
    
17.     call :calculate !StartingAddress! 4096 4K
    
18.     if "!4k!"=="!4k:.=!" (set 4k=是) else (set 4k=否)
    
19.     call :calculate !StartingAddress! 1048576 1M
    
20.     if "!1m!"=="!1M:.=!" (set 1m=是) else (set 1m=否)
    
21.     call :calculate !StartingAddress! 2097152 2M
    
22.     if "!2m!"=="!2M:.=!" (set 2m=是) else (set 2m=否)
    
23.     call :calculate !StartingAddress! 3145728 3M
    
24.     if "!3m!"=="!3M:.=!" (set 3m=是) else (set 3m=否)
    
25.     call :calculate !StartingAddress! 4194304 4M
    
26.     if "!4m!"=="!4M:.=!" (set 4m=是) else (set 4m=否)
    
27.     set availableGB=       !availableGB!
    
28.     set allGB=       !allGB!
    
29.     echo.总空间:!allGB:~-7!GB  可用:!availableGB:~-7!GB  4K(!4K!^)  1M(!1M!^)  2M(!2M!^)  3M(!3M!^)  4M(!4M!^)
    
30.     echo.
    
31.   )
    
32. )
    
33. del %temp%\tmp.vbs&echo.━━完成,按任意键退出.&pause>nul&exit
    
34. 
    
35. :calculate
    
36. for /f "delims=" %%i in ('cscript //nologo %temp%\tmp.vbs %1 %2') do (set %3=%%i)
    
37. goto :eof

复制代码

cjw00529017

否 就是没有对齐的意思吗

foxJL

回复 2# cjw00529017


    是的

林小七

好久没来了~版主就是狠~~

cc5511

回复 1# foxJL


    学习了 你这个检测4K对齐的关键命令是哪个啊 怎么判断的

ddvc

支持楼主，谢谢分享。