【练习-072】批处理按要求原样输出特殊字符文本内容

batman

出题目的：
    1、重温特殊字符输出处理方法；
    2、重温空行输出处理方法；
    3、学习局部变量传递方法。
加分原则：
    满分30分，视代码和思路酌情加分，以思路为重。
题目如下：
    有特殊字符文本a.txt，要求输出a.txt第8个含有&字符行前面所有行的内容，当然也包括空行。
在这里请注意这个8并不是指的文本的自然行，而是每当行中含有&字符计数加1，当计数达到8时
前面所有的行（含本行），之后的行就不要输出了（本题应输出并只输出到第19行）。总之，题目
说难不难，说易不易，大家都来晒晒自己的思路和技巧吧。
a.txt

1. 
   
2. }_){*|%<:\!`~"_.} =!>[."~|#+|
   
3. -|*#_[{\ ["",*@ >'+{+,\{[[:-`]
   
4. 
   
5. ;&'^;`|[^  @,{=?@;.}[-.:,.!|<#
   
6. :@"->\;#,%}%* (}"')('&-]=.`|{(
   
7. `>?||>[.'!_$`\#<+) <~<#>_&~\$`
   
8. !-~:@)/@][|>\~:}^/}.^!)=>-\,{^
   
9. 
   
10. $$*$*$^,]~".&#?_#;'(?)^>@\].{^
    
11. 
    
12. -~^/<_$}_/$.}_-(=]/})+%-"-^\]>
    
13. [<^._@|_?.";}[$'#]>");/-;!{#".
    
14. :,'_(}`@~-\]`)-> ]-.(;\'^]++,+
    
15. =+'/}]"`* #_ {[[;&{{)$|](,<]~/
    
16. .;@/<-^[*#=+~&%/;"=${|}?`.`_#/
    
17. 
    
18. =>>[@^]{.{<#>*`}]]([)/|]_#_/$/
    
19. ),\<.-<?"<\.))\',`@&&\+'+?`>}&
    
20. (%?<*{:\@/>;/=\`:|(}""~;`|[&?!
    
21. !^.}'~:[{(][\<'"=-^+#.*"/$(:&&
    
22. :^'`.{,"?@"~|(_`:(+<</({=+~-{|
    
23. ]!,|("|@[<#&^?;&](^~}%{!^),>./
    
24. !-~'- #}@(\>{#(,~*]=.`%_$@(`-*
    
25. (?~/]~#_#'-#\?![<?<.$][  @:?\?
    

复制代码

tmplinshi

1. @echo off
   
2. setlocal
   
3. 
   
4. for /f "delims=" %%a in (' findstr /n .* a.txt ') do (
   
5.     set str=%%a
   
6.     setlocal enabledelayedexpansion
   
7.     echo,!str:*:=!
   
8.    
   
9.     if "!str:&=!" neq "!str!" (
   
10.         endlocal
    
11.         set /a "count += 1, 1 / (count - 8)" 2>nul || goto finish
    
12.     ) else (
    
13.         endlocal
    
14.     )
    
15. )
    
16. 
    
17. :finish
    
18. echo 完成
    
19. pause

复制代码

terse

去掉FOR
搞来搞去 和版主一样 早知道不贴了

1. @echo off
   
2. set num=1
   
3. for /f "delims=" %%i in (' findstr /n .* a.txt ') do (
   
4.     set str=%%i
   
5.     setlocal enabledelayedexpansion
   
6.     if !num! leq 8 echo;!str:*:=!
   
7.     if "!str:&=!" neq "!str!" (
   
8.        endlocal&set /a num+=1
   
9.     ) else endlocal
   
10. )
    
11. pause

复制代码

tmplinshi

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set count=0
   
4. 
   
5. (
   
6.     for /f %%a in (' findstr /n .* a.txt ') do (
   
7.         set str=
   
8.         set /p str=
   
9.         echo,!str!
   
10.         
    
11.         set str=#!str!
    
12.         if "!str:&=!" neq "!str!" (
    
13.             set /a "count += 1, 1 / (count - 8)" 2>nul || goto finish
    
14.         )
    
15.     )
    
16. ) <a.txt
    
17. 
    
18. :finish
    
19. echo 完成
    
20. pause

复制代码

iBat

真是妙啊，用findstr /n 解决了输出空行的问题，利用零不能为除数判断输出完成。只是小弟有一处不解，为什么要分别endlocal，恳请版主解惑。先谢过啦！

CrLf

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f %%a in ('find /c /v ""^<a.txt') do (
   
3.         for /l %%b in (1 1 %%a) do (
   
4.                 set str=&set /p str=
   
5.                 if !n! lss 8 echo;!str!
   
6.                 if defined str if !str:^&^=! neq !str! set /a n+=1
   
7.         )
   
8. )<a.txt
   
9. pause

复制代码

再来个恶心的：

1. @echo off
   
2. for /f "tokens=1,2 delims=:" %%a in ('findstr /n "&" a.txt^|findstr /n .') do (
   
3.         echo %%a|find "8">nul&&for /f %%a in ('find /c /v ""^<a.txt') do set /a n=%%a-%%b
   
4. )
   
5. set n|findstr "^n=">nul 2>&1&&sort /+128 a.txt|more +%n%|sort /+128
   
6. pause

复制代码