[已解决]批处理如何获取网关和备用DNS？

dnvplj

请各位朋友帮忙:把网关和备用DNS项填上,谢谢了

1. @echo off
   
2. for /f "tokens=15" %%i in ('ipconfig /all ^| find /i "IP Address"') do set ip=%%i  
   
3. for /f "tokens=15" %%i in ('ipconfig /all ^| find /i "Subnet Mask"') do set mask=%%i
   
4. 本处填写:网关  
   
5. for /f "tokens=15" %%i in ('ipconfig /all ^| find /i "DNS Servers"') do set dns=%%i
   
6. 本处填写:备用DNS  
   
7. 
   
8. echo 本机IP为：%ip%  
   
9. echo 子网掩码：%mask%
   
10. echo 本机网关：
    
11. echo 首选 DNS：%dns%
    
12. echo 备用 DNS：  
    
13. paus

复制代码

tmplinshi

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. 
   
4. set command=" ipconfig /all | findstr /c:"IP Address" /c:"Subnet Mask" /rc:"Gateway.*[0-9].*" /c:"DNS Servers" /rc:"[ ][ ][ ]*[0-9]" "
   
5. 
   
6. for /f "tokens=1,2,*" %%a in (' %command% ') do (
   
7.     if "%%b"=="" (
   
8.         set DNS_Servers2=%%a
   
9.     ) else (
   
10.         set value=%%c
    
11.         set value=!value:*:=!
    
12.         set %%a_%%~nb=!value:* =!
    
13.     )
    
14. )
    
15. 
    
16. echo 本机IP为：%IP_Address%  
    
17. echo 子网掩码：%Subnet_Mask%
    
18. echo 本机网关：%Default_Gateway%
    
19. echo 首选 DNS：%DNS_Servers%
    
20. echo 备用 DNS：%DNS_Servers2%
    
21. pause

复制代码

dnvplj

谢谢板主,问题解决了.

dnvplj

回复 2# tmplinshi
版主您好，不好意思又打绕您，该代码在WIN7下只显示“备用DNS”其他的都没显示，如果在WIN7下显示应怎么写，请指教。

tmplinshi

回复 4# dnvplj
因为在 WIN7 下，ipconfig /all 输出的是汉化后的文字，所以导致 findstr 查找不到英文单词。

解决方法：

• 方法1：在 findstr 命令里，增加查找中文字符。
• 方法2：运行 chcp 437 将内部代码页切换为英文，再执行 ipconfig /all | findstr ...。
            如果之后你还要显示中文字符，那么还要运行 graftabl 936 启用中文字符集显示。
  1. @echo off
     
  2. setlocal enabledelayedexpansion
     
  3. CHCP 437 >nul
     
  4. 
     
  5. set command=" ipconfig /all | findstr /c:"IP Address" /c:"IPv4 Address" /c:"Subnet Mask" /rc:"Gateway.*[0-9].*" /c:"DNS Servers" /rc:"[ ][ ][ ]*[0-9]" "
     
  6. 
     
  7. for /f "tokens=1,2,*" %%a in (' %command% ') do (
     
  8.     if "%%b"=="" (
     
  9.         set DNS_Servers2=%%a
     
  10.     ) else (
      
  11.         set value=%%c
      
  12.         set value=!value:*:=!
      
  13.         set %%a_%%~nb=!value:* =!
      
  14.     )
      
  15. )
      
  16. 
      
  17. If not defined IP_Address (
      
  18.         for /f "delims=(" %%a in ("%IPv4_Address%") do (
      
  19.                 set "IP_Address=%%a"
      
  20.         )
      
  21. )
      
  22. 
      
  23. GRAFTABL 936 >nul
      
  24. echo 本机IP为：%IP_Address%  
      
  25. echo 子网掩码：%Subnet_Mask%
      
  26. echo 本机网关：%Default_Gateway%
      
  27. echo 首选 DNS：%DNS_Servers%
      
  28. echo 备用 DNS：%DNS_Servers2%
      
  29. pause

  复制代码

dnvplj

回复 5# tmplinshi
感谢版主的指教，我整不明白了，谢谢了。