【方案汇总】批处理标准化获取当前系统日期时间（20231002更新）
操作系统不同，日期格式也可能不同：星期二 2008-07-29
2008-07-29 星期二
07/29/2008 Tue
Tue 07/29/2008
再考虑到中、英之外的其它语言的操作系统，日期格式的种类实在太多了。要想标准化地获取当前系统日期20080728，以下两个方法都不好：
1. 直接使用系统变量 %date% 进行字符串截取
2. 直接对 date 命令的结果进行字符串截取
实际上日期格式是由注册表 HKEY_CURRENT_USER\Control Panel\International 里面 sShortDate 的值来决定的。
推荐使用其它方法来获取系统日期：
【方案1】BAT + PowerShell[code]@echo off
REM Win7/Win10/Win11等系统自带PowerShell
for /f %%i in ('powershell -c "Get-Date -uformat '%%Y%%m%%d'"') do (
set "Today=%%i"
)
echo,%Today%
pause
for /f "delims=" %%i in ('powershell -c "Get-Date -UFormat '%%Y-%%m-%%d %%H:%%M:%%S'"') do (
set "SysTS=%%i"
)
echo %SysTS%
pause[/code]【方案2】BAT + WMIC[code]@echo off
for /f "tokens=2 delims==" %%i in ('wmic path win32_operatingsystem get LocalDateTime /value ^| findstr "="') do (
set "strDate=%%i"
)
set "Today=%strDate:~0,4%%strDate:~4,2%%strDate:~6,2%"
echo,%Today%
pause
set "Now=%strDate:~0,4%-%strDate:~4,2%-%strDate:~6,2% %strDate:~8,2%:%strDate:~10,2%:%strDate:~12,2%"
echo %Now%
pause[/code]【方案3】BAT + mshta[code]@echo off
for /f %%i in ('mshta "vbscript:CreateObject("Scripting.FileSystemObject").GetStandardStream(1).WriteLine(Right(Year(Now),4)&Right("0"&Month(Now),2)&Right("0"&Day(Now),2))(Window.Close)"') do (
set "Today=%%i"
)
echo,%Today%
pause[/code]【方案4】BAT + VBS[code]@echo off
>"%temp%\DateCalculate.vbs" echo dt=date()
>>"%temp%\DateCalculate.vbs" echo s=right(year(dt),4) ^& "-" ^& right("0" ^& month(dt),2) ^& "-" ^& right("0" ^& day(dt),2)
>>"%temp%\DateCalculate.vbs" echo wscript.echo s
for /f %%a in ('cscript /nologo "%temp%\DateCalculate.vbs"') do (
set Today=%%a
)
echo,%Today%
pause[/code]【方案5】BAT + REG[code]@echo off
REM 无法保证在中、英之外的其它语言的操作系统上得到正确结果
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
set Today=%date: =%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set "Week=Mon Tue Wed Thu Fri Sat Sun 星期一 星期二 星期三 星期四 星期五 星期六 星期日"
for %%a in (%Week%) do (
call set "Today=%%Today:%%a=%%"
)
echo,%Today%
pause[/code]【方案6】BAT + REG[code]@echo off
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
set Today=%date: =%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
if "%Today:~0,1%" gtr "9" (
set Today=%Today:~-10%
) else (
set Today=%Today:~0,10%
)
echo,%Today%
pause[/code]【方案7】BAT + REG[code]@echo off
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
type nul>"%temp%\MyFile.tmp"
for /f %%a in ('dir "%temp%\MyFile.tmp" ^| findstr /i "MyFile.tmp"') do (
set Today=%%a
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
echo,%Today%
pause[/code]【方案8】BAT + REGEDIT[code]@echo off
REM 需要保证注册表编辑器没有处于锁定状态
regedit /e "%temp%\bak.reg" "HKEY_CURRENT_USER\Control Panel\International"
>"%temp%\new.reg" echo REGEDIT4
>>"%temp%\new.reg" echo,
>>"%temp%\new.reg" echo [HKEY_CURRENT_USER\Control Panel\International]
>>"%temp%\new.reg" echo "sShortDate"="yyyy-MM-dd"
regedit /s "%temp%\new.reg"
set Today=%date: =%
regedit /s "%temp%\bak.reg"
if "%Today:~0,1%" gtr "9" (
set Today=%Today:~-10%
) else (
set Today=%Today:~0,10%
)
echo,%Today%
pause[/code]【方案9】BAT + DEBUG[code]@echo off
for /f "tokens=6,8 delims== " %%a in ('^(echo a100^&echo mov ah^,2a^&echo int 21^&echo.^&echo p 2^&echo q^)^|debug^|find "CX"') do (
set /a y=0x%%a
set md=%%b
)
set /a m=0x%md:~,2%
set /a d=0x%md:~-2%
set m=0%m%
set d=0%d%
set Today=%y%-%m:~-2%-%d:~-2%
echo,%Today%
pause[/code][color=Blue]以下转载两个在DOS系统（不是Windows系统的CMD）里面获取日期、时间的代码：[/color]
原文：[url]http://www.cn-dos.net/forum/viewthread.php?tid=19756[/url]
【willsort原始版】[code]@echo off
if "%1"=="[(" goto parse
echo.|date|find "Current" > _getdate.bat
echo set _dw=%%3> current.bat
echo set _date=%%4>> current.bat
call _getdate.bat
echo.|date|find "Enter" > _getdfmt.bat
echo set _dfmt=%%3> enter.bat
call _getdfmt.bat
echo.|time|find "Current" > _gettime.bat
echo set _time=%%3> current.bat
call _gettime.bat
echo _|choice /c%_dfmt%%_date%_%_time%_ @%0 > _parse.bat
%comspec% /e:2048 /c _parse.bat
goto end
:parse
set _dt1=_%2%3
set _dt2=_%5%6
set _dt3=_%8%9
for %%t in ([,Y,Y,-,M,M,-,D,D,]) do shift
set _vdt=
:loop1
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop1
set %_dt1%=%_vdt%
set _vdt=
:loop2
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop2
set %_dt2%=%_vdt%
set _vdt=
:loop3
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop3
set %_dt3%=%_vdt%
set _vdt=
:loop4
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop4
set _HH=%_vdt%
set _vdt=
:loop5
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop5
set _MN=%_vdt%
set _vdt=
:loop6
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop6
set _SS=%_vdt%
set _vdt=
:loop7
shift
set _tmp=%_vdt%
for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
if not "%_vdt%"=="%_tmp%" goto loop7
set _CS=%_vdt%
echo DTN:%_YY% %_MM% %_DD% %_HH% %_MN% %_SS% %_CS%
:end[/code]【willsort简化版】[code]@echo off
if "%1"==":" goto %2 (subroutine handler at %2)
echo.exit|%comspec%/e:4096/k prompt set v=$d $t$_:>_tm.bat
call _tm.bat
echo.%v%&|%comspec%/e:4096/c %0 : Parse>_tm.bat
for %%p in (_tm.bat* _tmset.bat*) do call %%p
echo.Note that d1 d2 and d3 are in your system date order
echo.DTN:d1=%d1% d2=%d2% d3=%d3% hh=%hh% mm=%mm% ss=%ss% cs=%cs%.
for %%e in (v d1 d2 d3 hh mm ss cs) do set %%e=
for %%f in (_tm.bat* _tm.tmp* _tmset.bat*) do del %%f
goto end
:Parse (usage: call %0 : Parse +input redirect date/time)
set me=%0
set tok=d1 d2 d3 hh mm ss cs
set d1=
:NextToken
for %%v in (v1 v) do set %%v=
choice /c&0123456789 /n>_tm.tmp
for %%n in (0 1 2 3 4 5 6 7 8 9) do if errorlevel 77%%n set v=%%n
if not errorlevel 2 %me% : SetToken %tok%
find ""<_tm.tmp>nul
if not errorlevel 1 if not "%d1%"=="" call %me% : SetToken %tok%
set d1=%d1%%v%
goto NextToken
:SetToken
set tok=%4 %5 %6 %7 %8 %9
echo set %3=%d1%>> _tmset.bat
set d1=
goto end
:end (end-of-file)[/code] 作为个人作品，在小范围内流通不需要考虑这么多。。。
当然，鼓励LZ。。。 不错的总结。[code]wmic path win32_operatingsystem get LocalDateTime
即
wmic os get LocalDateTime[/code]纯P的话，这个我常用
回复 2楼 的帖子
确实如此。不过等你参加工作以后，可能会发现自己的代码需要兼容各种各样的环境。
^_^
回复 4楼 的帖子
我在win98 MS-DOS4.10下，就不能使用%time%来引用当前时间，echo %time%的结果还是%time%。这就是环境不同的结果吧。能告诉我为什么会这样呢？回复 5楼 的帖子
DOS系统里面没有%date%、%time%等环境变量，顶楼添加了两种在DOS系统里面的解决方案。 很多种方法，研究一下 mark一下，明日再研究 学习了，感谢楼主。 感谢分享！！！ 不错的分享 厉害👍🏻 [b]回复 [url=http://bbs.bathome.net/redirect.php?goto=findpost&pid=21862&ptid=3328]4#[/url] [i]Batcher[/i] [/b]主管，我想请问下关于日期的，下面这个代码是啥意思呀，可以解释一下吗
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
这个yy我计算出来是2021，搞不懂这一句，谢谢 [b]回复 [url=http://www.bathome.net/redirect.php?goto=findpost&pid=20936&ptid=3328]1#[/url] [i]Batcher[/i] [/b]
请问方案一里的today获取的是211021，如何才能获取20211021？
谢谢 [b]回复 [url=http://www.bathome.net/redirect.php?goto=findpost&pid=247097&ptid=3328]14#[/url] [i]jave000[/i] [/b][code]powershell -c "'{0:yyyyMMdd}' -f (get-date)"[/code] [b]回复 [url=http://www.bathome.net/redirect.php?goto=findpost&pid=247109&ptid=3328]15#[/url] [i]idwma[/i] [/b]
谢谢：）
BAT+WMIC获取任意格式日期时间timestamp、时区timezone
[i=s] 本帖最后由 Echo11 于 2022-2-23 08:22 编辑 [/i]该方案限制于WMIC，目前在win 11 22000.469 中测试。
据说未来win 11 会因安全问题去掉WMIC。
到时候想继续用WMIC，就需要在含有WMIC的系统版本中备份以下文件（不同语言需要备份对应语言的WMIC.exe.mui）：[quote]C:\Windows\System32\wbem\WMIC.exe
C:\Windows\System32\wbem\zh-CN\WMIC.exe.mui
[/quote]然后按原路径还原到不含WMIC的win XX系统。[code]:Solu9
REM 学习以下两个链接以及子链接中内容后融合Timezone数据编写，方便任意拼接
REM 【方案2】BAT + WMIC http://bbs.bathome.net/thread-3328-2-1.html
REM stackoverflow链接 https://stackoverflow.com/questions/11037831/filename-timestamp-in-windows-cmd-batch-script-getting-truncated
@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%" & set "Ms=%dt:~15,3%"
REM Ms 毫秒，这里我取了3位，按实际需求也可以取2位或1位
set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%.%Ms%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
REM 时区 方法1 继续从dt变量获取定位时区的相关值 Bias
REM UTC 偏移 +480分钟=+08小时
set "sign=%dt:~21,1%" & set "bias=%dt:~22,3%"
set /a "bias=bias/60+100"
echo timezone: "UTC%sign%%bias:~1,2%:00"
REM 时区 方法2 直接从 wmic TimeZone get Caption /value 提取时区信息
for /f "tokens=2 delims=^(^)" %%t in ('wmic TimeZone get Caption /value') do set "timezone=%%t"
echo timezone: "%timezone%"
pause
EXIT /B 0[/code]
[日期时间]批处理生成邮件头里的日期格式 （更新时间: 23 Feb 2022）
[i=s] 本帖最后由 Echo11 于 2022-2-23 13:08 编辑 [/i]（由于没有权限单独发帖。在此回复了。）
[size=6][b][日期时间]批处理生成邮件头里的日期格式[/b][/size][size=4] [u]（更新时间:Wed, 23 Feb 2022 12:29:34 +0800）[/u][/size]
[size=4]如：[b]Date: Wed, 23 Feb 2022 12:29:34 +0800[/b][/size]
[size=4]在用批处理发送邮件前需要生成“mail”本身，而mail包含mail header 和 mail content。mail header 遵从[b]RFC 5322[/b]标准。
Win系统中无法直接获取这种格式的日期时间，因此我写了这个批处理来干这件事。[/size]
[b][size=5]一、RFC 5322中关于日期的格式要求如下（非标准原文）：[/size][/b]
[quote]## Mail Date Reference
date = day month year ; 应当表示本地时间
time = time-of-day zone
----------------------------------------------------------------------------------------------
day-name = "Mon" / "Tue" / "Wed" / "Thu" / "Fri" / "Sat" / "Sun"
day = ([FWS] 1*2DIGIT FWS) / obs-day ; 一个月的第几天
month = "Jan" / "Feb" / "Mar" / "Apr" /
"May" / "Jun" / "Jul" / "Aug" /
"Sep" / "Oct" / "Nov" / "Dec"
year = (FWS 4*DIGIT FWS) / obs-year ; 四位数字
----------------------------------------------------------------------------------------------
time-of-day = hour ":" minute [ ":" second ] ; 应当表示本地时间, 一天中的时:分[:秒],
; 范围00:00:00 - 23:59:60
hour = 2DIGIT / obs-hour
minute = 2DIGIT / obs-minute
second = 2DIGIT / obs-second
zone = (FWS ( "+" / "-" ) 4DIGIT) / obs-zone
; date与time-of-day偏离UTC或GMT的偏差\
; +表示ahead of（即east of）UTC, -表示behind(即west of) UTC
; 前两个数字表示hours偏差, 后两个数字表示minutes偏差
; +hhmm表示 +(hh * 60 + mm) 分钟, -hhmm表示 -(hh * 60 + mm) 分钟
; "+0000"用于表示UTC的时区
; "-0000"用于表示本地时区生成的时间, date-time不包含本地时区的信息
sample:
Date: Wed, 23 Feb 2022 12:29:34 +0800[/quote]
[b][size=5]二、我的批处理[/size][/b][code]
:MailDate
REM 获取以下邮件头中的日期时间
REM Date: Wed, 23 Feb 2022 12:29:34 +0800
@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "year=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "day=%dt:~6,2%" & set "time-of-day=%dt:~8,2%:%dt:~10,2%:%dt:~12,2%"
set "dn1=Mon" & set "dn2=Tue" & set "dn3=Wed" & set "dn4=Thu" & set "dn5=Fri" & set "dn6=Sat" & set "dn7=Sun"
set "mon01=Jan" & set "mon02=Feb" & set "mon03=Mar" & set "mon04=Apr" & set "mon05=May" & set "mon06=Jun" & set "mon07=Jul" & set "mon08=Aug" & set "mon09=Sep" & set "mon10=Oct" & set "mon11=Nov" & set "mon12=Dec"
setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%b in ('wmic path win32_localtime Get DayOfWeek /value') do set "dow=%%b"
set "day-name=!dn%dow%!" & set month=!mon%MM%!
for /f "tokens=2 delims=^(^)" %%t in ('wmic TimeZone Get Caption /value') do set "zone=%%t"
set "zone=!zone:U=!" & set "zone=!zone:T=!" & set "zone=!zone:C=!" & set "zone=!zone::=!"
echo.Mail Date:
echo.Date: %day-name%, %day% %month% %year% %time-of-day% %zone%
endlocal
pause>nul
EXIT /B 0
[/code][b][size=5]三、执行结果如下：[/size][/b][code]Mail Date:
Date: Wed, 23 Feb 2022 12:43:00 +0800[/code] 感谢分享。最近正好需要在英文版系统和中文版系统间切换
页:
[1]