批处理游戏:老虎机
批处理模拟老虎机游戏...中奖几率大...大家快来赌钱吧!!![code]::Code By wankoilz 2011/5/28 @Win7 QQ375913828::From bbs.bathome.net 批处理之家
@echo off&setlocal enabledelayedexpansion
mode con lines=20 cols=40&title 老虎机—批处理之家&color 8e
echo;
echo;
echo 行赌生涯,老虎机玩法说明:
echo ┏━━━━━━━━━━━━━━┓
echo ┃初始金钱:1000 元 ┃
echo ┃中奖几率:7〈★〈 ■=◆=● ┃
echo ┃中奖情况:777=2000 ┃
echo ┃ ★★★=800 ┃
echo ┃ 77=500 ┃
echo ┃ ★★=300 ┃
echo ┃ ■■■=◆◆◆=●●●=500 ┃
echo ┃ ■■=◆◆=●●=100 ┃
echo ┗━━━━━━━━━━━━━━┛
echo 随着RMB的增加,头衔会升级哦
echo;
echo 准备好开始你的行赌生涯了吗?
echo 那么...按任意键开始吧!
pause>nul
set ta=●●●◆◆◆■■■★★7
for /l %%i in (1,1,7) do (set @%%i= &set $%%i= &set #%%i= )
for %%i in (赌棍 赌鬼 赌侠 赌王 赌圣 赌神 赌城老板 赌城老板娘) do set/a txph+=1&set tx!txph!=%%i
set "if=(if ^!@tmp^! gtr 7 (set/a @tmp=@tmp-7^&set/a rnd=^!random^!%%12^&for %%x in (^!rnd^!) do set @ta=^!ta:~%%x,1^!))"
set jq=1000&set txph=1
:start
set @4= &set $4= &set #4= &set zs=0
set/a @tmp=%random%%%7+1,$tmp=%random%%%7+1,#tmp=%random%%%7+1
set/a @rnd=%random%%%12,$rnd=%random%%%12,#rnd=%random%%%12
set @ta=!ta:~%@rnd%,1!&set $ta=!ta:~%$rnd%,1!&set #ta=!ta:~%#rnd%,1!
:lp
cls&echo;&setlocal&set/a zs+=1
%if%&%if:@=$%&%if:@=#%
set @!@tmp!=!@ta!&set $!$tmp!=!$ta!&set #!#tmp!=!#ta!
echo 头衔:!tx%txph%! Lv%txph%
echo 现有RMB %jq% 元
echo ┏━━━━┳━━━━┳━━━━┓
for /l %%j in (1,1,7) do echo ┃ !@%%j! ┃ !$%%j! ┃ !#%%j! ┃
echo ┗━━━━┻━━━━┻━━━━┛
if %zs% gtr 20 if %@tmp% equ 4 set/a @tmp=%@tmp%-1
if %zs% gtr 40 if %$tmp% equ 4 set/a $tmp=%$tmp%-1
if %zs% gtr 60 if %#tmp% equ 4 endlocal&set @4=%@4%&set $4=%$4%&set #4=%#4%&goto :js
endlocal&set/a @tmp=%@tmp%+1,$tmp=%$tmp%+1,#tmp=%#tmp%+1&set @ta=%@ta%&set $ta=%$ta%&set #ta=%#ta%&set zs=%zs%
for /l %%i in (1,1,50) do echo;>nul
goto :lp
:js
setlocal&set zjsm=1&echo;
for %%i in (!@4! !$4! !#4!) do (
if defined %%i (set/a zjsm+=1&set zjta=%%i)
set %%i=ok
)
if %zjsm% equ 1 echo 郁闷,貌似啥都没中...赔了50元&set/a jq-=50
if %jq% leq 0 echo;&echo 输得个精光,行赌生涯到此为止了!&pause>nul&exit
if %zjsm% equ 2 (
if "%zjta%"=="7" (echo 很好很好,中了%zjsm%个%zjta%...赚得500元&set/a jq+=500
) else (
if "%zjta%"=="★" (echo 运气不错,中了%zjsm%个%zjta%...赢了300元&set/a jq+=300
) else (
echo 还过得去,中了%zjsm%个%zjta%...赚了100元&set/a jq+=100
)))
if %zjsm% equ 3 (
if "%zjta%"=="7" (echo 老天开眼,你中了大奖%zjsm%个%zjta%
echo 一次赚取2000元,赶紧娶媳妇去吧&set/a jq+=2000
) else (
if "%zjta%"=="★" (echo 不可思议,你中了%zjsm%个%zjta%...赢了800元&set/a jq+=800
) else (
echo 财神保佑,你中了%zjsm%个%zjta%...进账500元&set/a jq+=500
)))
for %%i in (0 1300 1600 1900 2300 2800 3200 4000) do (if %jq% geq %%i set/a jqph+=1)
if %jqph% gtr %txph% set txph=%jqph%&echo;&echo 等级提升为→!tx%jqph%! Lv%jqph%
if %jqph% lss %txph% set txph=%jqph%&echo;&echo 等级降低为→!tx%jqph%! Lv%jqph%
echo;&echo 按任意键,再试试运气吧
pause>nul&endlocal&set jq=%jq%&set txph=%txph%&goto :start[/code] 这个。。。。太强了。。我无语了。。 每次跑龙套的时间可以放长点哦。。。 把45,46,47行的20,40,60改大一点就可以增加“跑龙套”时间了 强悍呀,这游戏好玩呀,呵呵 哈哈,好喜欢玩这个游戏。我已经变成赌徒了 楼上运气不错嘛... 你们都没我牛 [b]回复 [url=http://bbs.bathome.net/redirect.php?goto=findpost&pid=80749&ptid=12559]1#[/url] [i]wankoilz[/i] [/b]
问下哦~那个往下滚的效果是怎样实现的? 有点意思 玩什么都是的,一修改无敌后就玩不下去了 改版,把里面的线条对齐[code]::Code By wankoilz 2011/5/28 @Win7 QQ375913828
::From bbs.bathome.net 批处理之家
@echo off&setlocal enabledelayedexpansion
mode con lines=20 cols=40&title 老虎机&color 8e
echo;
echo;
echo 行赌生涯,老虎机玩法说明:
echo ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
echo ┃初始金钱:1000 元 ┃
echo ┃中奖几率:7〈★〈 ■=◆=● ┃
echo ┃中奖情况:777=2000 ┃
echo ┃ ★★★=800 ┃
echo ┃ 77=500 ┃
echo ┃ ★★=300 ┃
echo ┃ ■■■=◆◆◆=●●●=500 ┃
echo ┃ ■■=◆◆=●●=100 ┃
echo ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
echo 随着RMB的增加,头衔会升级哦
echo;
echo 准备好开始你的行赌生涯了吗?
echo 那么...按任意键开始吧!
pause>nul
set ta=●●●◆◆◆■■■★★7
for /l %%i in (1,1,7) do (set @%%i= &set $%%i= &set #%%i= )
for %%i in (赌棍 赌鬼 赌侠 赌王 赌圣 赌神 赌城老板 赌城老板娘) do set/a txph+=1&set tx!txph!=%%i
set "if=(if ^!@tmp^! gtr 7 (set/a @tmp=@tmp-7^&set/a rnd=^!random^!%%12^&for %%x in (^!rnd^!) do set @ta=^!ta:~%%x,1^!))"
set jq=1000&set txph=1
:start
set @4= &set $4= &set #4= &set zs=0
set/a @tmp=%random%%%7+1,$tmp=%random%%%7+1,#tmp=%random%%%7+1
set/a @rnd=%random%%%12,$rnd=%random%%%12,#rnd=%random%%%12
set @ta=!ta:~%@rnd%,1!&set $ta=!ta:~%$rnd%,1!&set #ta=!ta:~%#rnd%,1!
:lp
cls&echo;&setlocal&set/a zs+=1
%if%&%if:@=$%&%if:@=#%
set @!@tmp!=!@ta!&set $!$tmp!=!$ta!&set #!#tmp!=!#ta!
echo 头衔:!tx%txph%! Lv%txph%
echo 现有RMB %jq% 元
echo ┏━━━━━━━━┳━━━━━━━━┳━━━━━━━━┓
for /l %%j in (1,1,7) do echo ┃ !@%%j! ┃ !$%%j! ┃ !#%%j! ┃
echo ┗━━━━━━━━┻━━━━━━━━┻━━━━━━━━┛
if %zs% gtr 20 if %@tmp% equ 4 set/a @tmp=%@tmp%-1
if %zs% gtr 40 if %$tmp% equ 4 set/a $tmp=%$tmp%-1
if %zs% gtr 60 if %#tmp% equ 4 endlocal&set @4=%@4%&set $4=%$4%&set #4=%#4%&goto :js
endlocal&set/a @tmp=%@tmp%+1,$tmp=%$tmp%+1,#tmp=%#tmp%+1&set @ta=%@ta%&set $ta=%$ta%&set #ta=%#ta%&set zs=%zs%
for /l %%i in (1,1,50) do echo;>nul
goto :lp
:js
setlocal&set zjsm=1&echo;
for %%i in (!@4! !$4! !#4!) do (
if defined %%i (set/a zjsm+=1&set zjta=%%i)
set %%i=ok
)
if %zjsm% equ 1 echo 郁闷,貌似啥都没中...赔了50元&set/a jq-=50
if %jq% leq 0 echo;&echo 输得个精光,行赌生涯到此为止了!&pause>nul&exit
if %zjsm% equ 2 (
if "%zjta%"=="7" (echo 很好很好,中了%zjsm%个%zjta%...赚得500元&set/a jq+=500
) else (
if "%zjta%"=="★" (echo 运气不错,中了%zjsm%个%zjta%...赢了300元&set/a jq+=300
) else (
echo 还过得去,中了%zjsm%个%zjta%...赚了100元&set/a jq+=100
)))
if %zjsm% equ 3 (
if "%zjta%"=="7" (echo 老天开眼,你中了大奖%zjsm%个%zjta%
echo 一次赚取2000元,赶紧娶媳妇去吧&set/a jq+=2000
) else (
if "%zjta%"=="★" (echo 不可思议,你中了%zjsm%个%zjta%...赢了800元&set/a jq+=800
) else (
echo 财神保佑,你中了%zjsm%个%zjta%...进账500元&set/a jq+=500
)))
for %%i in (0 1300 1600 1900 2300 2800 3200 4000) do (if %jq% geq %%i set/a jqph+=1)
if %jqph% gtr %txph% set txph=%jqph%&echo;&echo 等级提升为→!tx%jqph%! Lv%jqph%
if %jqph% lss %txph% set txph=%jqph%&echo;&echo 等级降低为→!tx%jqph%! Lv%jqph%
echo;&echo 按任意键,再试试运气吧
pause>nul&endlocal&set jq=%jq%&set txph=%txph%&goto :start[/code] [quote]改版,把里面的线条对齐
[size=2][color=#999999]X1950440120 发表于 2022-4-7 17:23[/color] [url=http://www.bathome.net/redirect.php?goto=findpost&pid=253937&ptid=12559][img]http://www.bathome.net/images/common/back.gif[/img][/url][/size][/quote]
强迫症超晚期 运气太好了,一会就去澳门试试
页:
[1]